
Req is a batteries-included HTTP client for Elixir.
With just a couple lines of code:
Mix.install([
  {:req, "~> 0.8.0-rc"}
])

Req.get!("https://api.github.com/repos/wojtekmach/req").body["description"]
#=> "Req is a batteries-included HTTP client for Elixir."
we get automatic response body decoding, following redirects, retrying on errors,
and much more. Virtually all of the features are broken down into individual pieces called
steps. You can easily re-use and re-arrange built-in steps and write new ones.
New Internals in Req v0.8
Req v0.8 contains revamped internals. Most end-users should be unaffected,
but if you're using custom steps or plugins, response and error steps are now
deprecated in favour of step wrappers. Check out
"Steps & Step Wrappers" section in
Req.Request module documentation for more information.
Features
	An easy to use high-level API: Req.request/1, Req.stream/4, Req.new/1, Req.get!/2, Req.post!/2, etc.

	Extensibility via steps.

	Request body compression, see compress_body.

	Opt-in response body decompression, see Req.Decompress. Supports gzip, brotli, and zstd.

	Request body encoding. Supports urlencoded/multipart forms, and JSON, see encode_body.

	Automatic response body decoding, see Req.Decode.

	Encode params as query string, see put_params.

	Setting base URL, see put_base_url.

	Templated request paths, see put_path_params.

	Basic, Digest, Bearer, and .netrc-based authentication, see Req.Auth.

	Range requests, see put_range.

	Use AWS V4 Signature, see put_aws_sigv4.

	Request body streaming by setting body: enumerable or body: fun.

	Response body streaming via Req.stream/4 or by setting into: collectable or into: :self.

	Follows redirects, see Req.Redirect.

	Retries on errors, see Req.Retry.

	Raise on unexpected response status, see Req.Expect.

	Verify response body against a checksum, see Req.Checksum.

	Plug-based HTTP mocks and stubs, see Req.Test.

	Running against a plug, see Req.Plug.

	Pluggable adapters. By default, Req uses Finch, see Req.Finch adapter.


Usage
The easiest way to use Req is with Mix.install/2:
Mix.install([
  {:req, "~> 0.8.0-rc"}
])

Req.get!("https://api.github.com/repos/wojtekmach/req").body["description"]
#=> "Req is a batteries-included HTTP client for Elixir."
Here's an example POST with JSON data:
iex> Req.post!("https://httpbingo.org/post", json: %{x: 1, y: 2}).body["json"]
%{"x" => 1, "y" => 2}
You can stream request body:
iex> stream = Stream.duplicate("foo", 3)
iex> Req.post!("https://httpbingo.org/post", body: stream, headers: [content_type: "text/plain"]).body["data"]
"foofoofoo"
and stream the response with a callback function:
iex> Req.stream(
...>   "https://stream.wikimedia.org/v2/stream/recentchange",
...>   nil,
...>   fn event, _resp, acc ->
...>     %{"type" => type, "title" => title} = JSON.decode!(event.data)
...>     IO.puts("#{type}: #{title}")
...>     {:cont, acc}
...>   end
...> )
# Output: edit: File:Glacier National Park (GeoDIL number - 2068).jpg
# Output: categorize: Category:Coins of Merovingian dynasty from Gallica
# ...
Or into a Collectable:
iex> resp = Req.get!("http://httpbingo.org/stream/2", into: IO.stream())
# Output: {"url": "http://httpbingo.org/stream/2", ...}
# Output: {"url": "http://httpbingo.org/stream/2", ...}
iex> resp.status
200
iex> resp.body
%IO.Stream{...}
(See Req module documentation for more examples of response body streaming.)
If you are planning to make several similar requests, you can build up a request struct with
desired common options and re-use it:
req = Req.new(base_url: "https://api.github.com")

Req.get!(req, url: "/repos/sneako/finch").body["description"]
#=> "Elixir HTTP client, focused on performance"

Req.get!(req, url: "/repos/elixir-mint/mint").body["description"]
#=> "Functional HTTP client for Elixir with support for HTTP/1 and HTTP/2."
See Req.new/1 for more information on available options.
Virtually all of Req's features are broken down into individual pieces --
steps. You can easily reuse or rearrange built-in steps or write new ones.
Here is another example where we append a request step that inspects the URL
just before requesting it:
req =
  Req.new(base_url: "https://api.github.com")
  |> Req.Request.append_request_steps(
    debug_url: fn request ->
      IO.inspect(URI.to_string(request.url))
      request
    end
  )

Req.get!(req, url: "/repos/wojtekmach/req").body["description"]
# Output: "https://api.github.com/repos/wojtekmach/req"
#=> "Req is a batteries-included HTTP client for Elixir."
Custom steps can be packaged into plugins so that they are even easier to use by others. See Related Packages.
Here is how they can be used:
Mix.install([
  {:req, "~> 0.8.0-rc"},
  {:req_easyhtml, "~> 0.2.0"},
  {:req_s3, "~> 0.2.3"},
  {:req_hex, "~> 0.2.0"},
  {:req_github_oauth, "~> 0.1.0"}
])

req =
  (Req.new(http_errors: :raise)
  |> ReqEasyHTML.attach()
  |> ReqS3.attach()
  |> ReqHex.attach()
  |> ReqGitHubOAuth.attach())

Req.get!(req, url: "https://elixir-lang.org").body[".entry-summary h5"]
#=>
# #EasyHTML[<h5>
#    Elixir is a dynamic, functional language for building scalable and maintainable applications.
#  </h5>]

Req.get!(req, url: "s3://ossci-datasets/mnist/t10k-images-idx3-ubyte.gz").body
#=> <<0, 0, 8, 3, ...>>

Req.get!(req, url: "https://repo.hex.pm/tarballs/req-0.1.0.tar").body["metadata.config"]["links"]
#=> %{"GitHub" => "https://github.com/wojtekmach/req"}

Req.get!(req, url: "https://api.github.com/user").body["login"]
# output:
# paste this user code:
#
#   6C44-30A8
#
# at:
#
#   https://github.com/login/device
#
# open browser window? [Yn]
# 15:22:28.350 [info] response: authorization_pending
# 15:22:33.519 [info] response: authorization_pending
# 15:22:38.678 [info] response: authorization_pending
#=> "wojtekmach"

Req.get!(req, url: "https://api.github.com/user").body["login"]
#=> "wojtekmach"
See Req.Request module documentation for more information on low-level API, request struct, and developing plugins.
Configuration
Req supports many configuration options, see Req.new/1 for a full list and see each step for
more details. In particular, if you are looking for slightly lower level HTTP options such as
timeouts, pool sizes, and certificates, see the Req.Finch documentation.
Related Packages
There are many packages that extend the Req library. To get yours listed here, send a PR.
	req_easyhtml
	req_s3
	req_hex
	req_github_oauth
	curl_req
	http_cookie
	req_embed
	req_proxy

Presentations
	Building API Clients with Req -- ElixirConf EU 2024
	Req: A batteries-included HTTP client for Elixir -- ElixirConf 2023

Development
When developing on macOS, you may need the following linker flags in order to successfully compile Brotli.
export LDFLAGS="-undefined dynamic_lookup -dynamiclib"

Acknowledgments
Req is built on top of Finch and is inspired by cURL, Requests, Tesla, and many other HTTP clients - thank you!
License
Copyright (c) 2021 Wojtek Mach
Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at http://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.


  

    CHANGELOG

v0.8.0-rc.0 (2026-08-18)
Req v0.8 brings more ergonomic streaming with Req.stream/4, streaming decompression and decoding, automatic NDJSON & SSE decoding, and more.
Req v0.8 has revamped internals though most end-users should be unaffected. Req's initial design included response/error steps which are now deprecated as we couldn't use them for extensible streaming decoding. Instead, we're adding step wrappers.
See "Steps & Step Wrappers" section in Req.Request module documentation for more information.
Req v0.8 requires Elixir 1.18+.
Enhancements
	Req: Add Req.stream/4.

	Req: Allow setting private through options, e.g.: Req.new(private: %{foo: :bar}).

	Req: Support request body streaming with body: fun

	Req.Response: Add resp.request. This is useful to inspect the final request after all steps have executed.

	Req.Decode: Support NDJSON

	Req.Decode: Support SSE

	Req.Decode: Support decoders: [{content_type, decoder}].


Breaking Changes
	Remove jason dependency. Req.post(url, json: term) will now use JSON.encode!/2, not Jason.encode!/2, that is, term must implement JSON.Encoder protocol.
	Remove deprecated :finch_request option
	Remove deprecated into: :legacy_self
	Remove deprecated cache step
	Replace compressed and decompress_body with Req.Decompress.
	Replace handle_http_errors with Req.Expect.
	Replace auth and http_digest steps with Req.Auth.
	Replace redirect with Req.Redirect
	Replace retry with Req.Retry
	Replace checksum with Req.Checksum
	Replace decode_body with Req.Decode

Deprecations
	Req: Deprecate into: fun in favour of Req.stream/4.
	Req.Expect: Deprecate :http_errors option in favour of :expect.

v0.7.2 (2026-07-31)
	encode_body: Bring back form_multipart: [{string_name, value}].
	put_aws_sigv4: Fix AWS SigV4 compatibility with Supabase Storage S3.

v0.7.1 (2026-07-28)
	Deprecate cache: true/cache step. It will be removed in Req v0.8. I plan a comprehensive cache solution for Req v1.0+.

v0.7.0 (2026-07-28)
	Req: Add Req.new(req, options).

	Req: Treat URL userinfo as Basic Authentication.

	Req, Req.Request: Deprecate adapter: fun in favour of adapter: mod.

	Req.Request: (BREAKING CHANGE) Remove current_request_steps field.

	Req.Request: Fix redacting remaining auth values.

	(BREAKING CHANGE) Replace run_finch step with Req.Finch adapter module.

	(BREAKING CHANGE) Replace put_plug and run_plug steps with Req.Plug adapter module.

	Req.Finch: Support finch: options.

	Req.Finch: Support :request_timeout.

	Req.Finch: Fix handling duplicate response headers.

	Req.Finch: Deprecate finch: name in favour of finch: [name: name].

	Req.Finch: Deprecate pool_timeout: value in favour of finch: [pool_timeout: value].

	Req.Finch: Deprecate pool_max_idle_time: value in favour of finch: [pool_max_idle_time: value].

	Req.Finch: Deprecate :finch_request.

	Req.Plug: Handle individual response body chunks.

	Req.Plug: Support non-UTF8 request params.

	Req.Plug: Put original request private data in conn.private.

	Req.Test: Allow descendant processes.

	Req.Test: Fix concurrent plug fetches immediately after switching to shared mode.

	compress_body: Do nothing when request content-encoding is already set.

	compress_body: Update multipart boundary when re-running the step.

	compressed, decode_body: Replace optional ezstd dependency with Erlang/OTP 28+
built-in :zstd.

	decode_body: Deprecate :decode_json in favour of setting a custom JSON
decoder via :decoders:
# before:
Req.get!(url, decode_json: [keys: :atoms])

# after:
Req.get!(url, decoders: [json: &Jason.decode(&1, keys: :atoms)])

	encode_body: (BREAKING CHANGE) Automatically change GET to POST when request body is set.

	put_aws_sigv4: Exclude accept-encoding, x-amzn-trace-id, and
hop-by-hop headers from the signature.

	put_aws_sigv4: Correctly sign duplicate header values.

	put_params: (BREAKING CHANGE) Overwrite existing query params instead of appending.

	put_path_params: Preserve the path template when re-running the step.

	redirect: Strip userinfo from redirect locations and log a warning.
Previously, redirecting to a URL with userinfo (e.g. http://user:pass@host)
kept the userinfo in the request URL (without converting it to auth). It is
now dropped so credentials supplied by the redirecting server aren't sent.

	redirect: Clear the request body, body options, and content headers when
changing POST to GET after a 301, 302, or 303 response.

	retry: Use jitter by default.

	retry: Honor configured :retry_delay over Retry-After.

	(BREAKING CHANGE) Remove deprecated follow_redirects step.

	(BREAKING CHANGE) Remove deprecated output step.

	Require Elixir 1.15 or later.


v0.6.3 (2026-07-16)
	Req.Test: Fix __fetch_plug__/1 when called immediately after switching to shared mode.

v0.6.2 (2026-06-19)
	Use finch ~> 0.21.

v0.6.1 (2026-06-08)
	compressed, decompress_body: Disable automatic decompression
Decompression is now opt-in by setting compressed: true.


v0.6.0 (2026-06-08)
	encode_body: Security fix for :form_multipart header injection
(GHSA-px9f-whj3-246m).
The multipart encoder interpolated the per-part name, filename, and
content_type into the part headers without escaping, so an
attacker-controlled value could inject extra headers or smuggle additional
parts into the request. These values are now escaped per RFC 7578 / WHATWG
form-data (", CR, and LF are percent-encoded).
Thanks to @PJUllrich for reporting it.

	decode_body: Drop automatic zip/tar/tgz/gz/zst/csv decoding,
(GHSA-655f-mp8p-96gv).
Req previously auto-decoded archive and compressed response bodies (zip,
tar, tgz, gz, zst, and csv) based on the server-supplied
content-type, materialising the full decompressed contents in memory with
no size cap. An attacker-controlled (or redirect-reachable) endpoint could
return a tiny "decompression bomb" that expanded to gigabytes and exhausted
the node's memory.
Now only JSON is decoded by default. Other formats are opt-in via the new
:decoders option, which defaults to [:json, :json_api]. Setting it
replaces the default (include :json to keep JSON decoding), and false
disables all decoding:
# opt into archives (only for endpoints you trust):
Req.get!(url, decoders: [:json, :zip])
Note: The decoded zip/tar is still list of
{filename :: charlist(), contents :: binary} tuples.
In the future release, this will be list of
{filename :: binary(), contents :: binary()} tuples.
While automatic CSV decoding wasn't a security issue, the behaviour based
on presence/absence of nimble_csv dependency was suprising. CSV support
is still built-in but need to be enabled with decoders: [:csv].
Custom decoders are supported via {format, codec} tuples, where codec is
a module exporting decode/1 or a 1-arity function returning an :ok/:error
tuple, for example:
Req.get!(url, decoders: [:json, ics: &{:ok, ICal.from_ics(&1)}])
Thanks to @PJUllrich for reporting it.


v0.5.18 (2026-05-20)
	run_finch: Allow :finch option with IPv6 URLs.

	run_finch: Normalize Finch.TransportError and Finch.HTTPError
(introduced in Finch v0.22.0) into Req.TransportError and Req.HTTPError.

	retry: Automatically retry on :pool_not_available.

	Require Finch ~> 0.21.0 or ~> 0.22.0.


v0.5.17 (2026-01-22)
	retry: Use default delay if retry-after is "negative"
Previously, we were only handling "negative" retry-after in "http date"
format and slept for zero seconds. We were crashing on retry-after with
negative seconds.
Now, we're using the default delay (1s, 2s, 4s, ...) in either format.


v0.5.16 (2025-11-10)
	Req.Test: Fix verify_on_exit! accidentally using Mox name
	auth: Support MFArgs
	auth: Support digest auth
	put_aws_sigv4: Support MFArgs
	put_path_params: Encode :path_params even with reserved characters
	put_path_params: Set :path_params_template on empty params
	run_plug: Handle compressed request body

v0.5.15 (2025-07-14)
	Req.Response: Add Req.Response.to_map/1.

v0.5.14 (2025-07-02)
	run_plug: Remove warning about into: fun with {:halt, acc} result.
The warning never been particularly useful because it's not like users
can do anything about it.


v0.5.13 (2025-07-02)
	run_plug: Ease transition to automatically parsing request body.
Since v0.5.11, this code:
plug = fn conn ->
  {:ok, body, conn} = Plug.Conn.read_body(conn)
  assert JSON.decode!(body) == %{"x" => 1}
  Plug.Conn.send_resp(conn, 200, "ok")
end

Req.put!(plug: plug, json: %{x: 1})
 Needed to be updated to:
plug = fn conn ->
  assert conn.body_params == %{"x" => 1}
  Plug.Conn.send_resp(conn, 200, "ok")
end

Req.put!(plug: plug, json: %{x: 1})
This change makes it so both work. The latter will be required, however.


v0.5.12 (2025-06-24)
	run_plug: Do not raise on unknown content types.

	Req.Test: Improve Req.Test.transport_error/2 error message.


v0.5.11 (2025-06-23)
	encode_body: Fix leading newline before multipart body.

	run_finch: Handle initial transport errors on into: :self.

	run_plug: Automatically parse request body.
Prior to this change, users would typically write:
plug = fn conn ->
  {:ok, body, conn} = Plug.Conn.read_body(conn)
  assert JSON.decode!(body) == %{"x" => 1}
  Plug.Conn.send_resp(conn, 200, "ok")
end

Req.put!(plug: plug, json: %{x: 1})
Now, it can be:
plug = fn conn ->
  assert conn.params == %{"x" => 1}
  Plug.Conn.send_resp(conn, 200, "ok")
end

Req.put!(plug: plug, json: %{x: 1})
This is a breaking change as Plug.Conn.read_body will now return "".
It can be easily fixed by using Req.Test.raw_body/1 which returns copy of
the request raw body:
- {:ok, body, conn} = Plug.Conn.read_body(conn)
+ body = Req.Test.raw_body(conn)
Furthermore, prior to this change conn.body_params was unfetched:
plug = fn conn ->
  Plug.Conn.send_resp(conn, 200, inspect(conn.body_params))
end

iex> Req.post!(json: %{a: 1}, plug: plug).body
"%Plug.Conn.Unfetched{aspect: :body_params}"
Now it is:
iex> Req.post!(json: %{a: 1}, plug: plug).body
"%{\"a\": 1}"
If in your :plug usage you look at conn.params, it will
now include conn.body_params as Plug always merges them.

	retry: Use jitter by default

	Req.Request: Add Req.Request.put_option/3.

	Req.Request: Add Req.Request.put_new_option/3.

	Req.Request: Add Req.Request.merge_new_options/2.

	Req.Test: Add [Req.Test.redirect/2].


v0.5.10 (2025-03-21)
	Req: Add Req.get_headers_list/1.

v0.5.9 (2025-03-17)
	encode_body: Support any enumerable in :form_multipart

	Req.Test.expect/3: Fix usage in shared mode

	retry: Do not carry halt between retries

	(Internal) Support custom headers in Req.Utils.aws_sigv4_url/1

	(Internal) Support custom query params in Req.Utils.aws_sigv4_url/1


v0.5.8 (2024-11-29)
	Req: Check legacy headers when streaming headers

	Req: Ignore :into collectable for non-200 responses

	put_aws_sigv4: Fix encoding path

	run_finch: Add option to configure Finch :pool_max_idle_time

	run_finch: Prepare for upcoming Finch v0.20


v0.5.7 (2024-10-29)
	put_aws_sigv4: Fix signature when using custom port

	retry: Do not call retry_delay fun twice

	auth: Support passing a 0-arity function


v0.5.6 (2024-08-01)
	Fix compatibility with Elixir v1.13

v0.5.5 (2024-08-01)
	put_aws_sigv4: Fix detecting service

	put_aws_sigv4: Raise on no :access_key_id/:secret_access_key/:service

	put_aws_sigv4: Fix handling ?name (no value)

	handle_http_errors: should run before verify_checksum

	encode_body: Support %File.Stream{} in :form_multipart

	encode_body: Support %File.Stream{} from other nodes in :form_multipart


v0.5.4 (2024-07-18)
	run_finch, Req.parse_message/2: Gracefully handle process messages not meant
for the asynchronous response. In that case, Req.parse_message/2 returns :unknown.

v0.5.3 (2024-07-18)
	Req.Test: Fix using shared mode

	encode_body: Add :form_multipart option

	put_aws_sigv4: Try detecting the service

	run_finch: Fix setting :finch option


v0.5.2 (2024-07-08)
	put_aws_sigv4: Fix bug when using custom headers

	put_aws_sigv4: Add :token option

	redirect: Cancel async request before redirecting

	decode_body: Support application/zstd and .zst


v0.5.1 (2024-06-24)
	retry: Default :retry_log_level to :warning

	put_path_params: Add :path_params_style option

	put_aws_sigv4: Fix path encoding

	decode_body: Improve tar detection

	run_finch: Fix defaulting to using just HTTP/1


v0.5.0 (2024-05-28)
Req v0.5.0 brings testing enhancements, errors standardization, %Req.Response.Async{}, and more improvements and bug fixes.
Testing Enhancements
In previous releases, we could only create test stubs (using Req.Test.stub/2), that is, fake
HTTP servers which had predefined behaviour. Let's say we're integrating with a third-party
weather service and we might create a stub for it like below:
Req.Test.stub(MyApp.Weather, fn conn ->
  Req.Test.json(conn, %{"celsius" => 25.0})
end)
Anytime we hit this fake we'll get the same result. This works extremely well for simple
integrations however it's not quite enough for more complicated ones. Imagine we're using
something like AWS S3 and we test uploading some data and reading it back again. While we could do
this:
Req.Test.stub(MyApp.S3, fn
  conn when conn.method == "PUT" ->
    # ...

  conn when conn.method == "GET" ->
    # ...
end)
making the test just a little bit more thorough will make it MUCH more complicated, for example:
the first GET request should return a 404, we then make a PUT, and now GET should return a 200.
We could solve it by adding some state to our test (e.g. an agent) but there is a simpler way and
that is to set request expectations using the new Req.Test.expect/3 function:
Req.Test.expect(MyApp.S3, fn conn when conn.method == "GET" ->
  Plug.Conn.send_resp(conn, 404, "not found")
end)

Req.Test.expect(MyApp.S3, fn conn when conn.method == "PUT" ->
  {:ok, body, conn} = Plug.Conn.read_body(conn)
  assert body == "foo"
  Plug.Conn.send_resp(conn, 200, "")
end)

Req.Test.expect(MyApp.S3, fn conn when conn.method == "GET" ->
  Plug.Conn.send_resp(conn, 200, "foo")
end)
The important part is the request expectations are meant to run in order (and fail if they don't).
In this release we're also adding Req.Test.transport_error/2, a way to simulate network
errors.
Here is another example using both of the new features, let's simulate a server that is
having issues: on the first request it is not responding and on the following two requests it
returns an HTTP 500. Only on the fourth request it returns an HTTP 200. Req by default
automatically retries transient errors (using retry step) so it will make multiple
requests exercising all of our request expectations:
iex> Req.Test.expect(MyApp.S3, &Req.Test.transport_error(&1, :econnrefused))
iex> Req.Test.expect(MyApp.S3, 2, &Plug.Conn.send_resp(&1, 500, "internal server error"))
iex> Req.Test.expect(MyApp.S3, &Plug.Conn.send_resp(&1, 200, "ok"))
iex> Req.get!(plug: {Req.Test, MyApp.S3}).body
# 15:57:06.309 [error] retry: got exception, will retry in 1000ms, 3 attempts left
# 15:57:06.309 [error] ** (Req.TransportError) connection refused
# 15:57:07.310 [error] retry: got response with status 500, will retry in 2000ms, 2 attempts left
# 15:57:09.311 [error] retry: got response with status 500, will retry in 4000ms, 1 attempt left
"ok"
Finally, for parity with Mox, we add functions for setting ownership
mode:
	Req.Test.set_req_test_from_context/1
	Req.Test.set_req_test_to_private/1
	Req.Test.set_req_test_to_shared/1

And for verifying expectations:
	Req.Test.verify!/0
	Req.Test.verify!/1
	Req.Test.verify_on_exit!/1

Thanks to Andrea Leopardi for driving the testing improvements.
Standardized Errors
In previous releases, when using the default adapter, Finch, Req could return these exceptions on
network/protocol errors: Mint.TransportError, Mint.HTTPError, and Finch.Error. They have
now been standardized into: Req.TransportError and Req.HTTPError for more consistent
experience. In fact, this standardization was the pre-requisite of adding
Req.Test.transport_error/2!
Two additional exception structs have been added: Req.ArchiveError and Req.DecompressError
for zip/tar/etc errors in decode_body and gzip/br/zstd/etc errors in decompress_body
respectively. Additionally, decode_body now returns Jason.DecodeError instead of raising it.
%Req.Response.Async{}
In previous releases we added ability to stream response body chunks into the current process
mailbox using the into: :self option. When such is used, the response.body is now set to
Req.Response.Async struct which implements the Enumerable protocol.
Here's a quick example:
resp = Req.get!("http://httpbingo.org/stream/2", into: :self)
resp.body
#=> #Req.Response.Async<...>
Enum.each(resp.body, &IO.puts/1)
# {"url": "http://httpbingo.org/stream/2", ..., "id": 0}
# {"url": "http://httpbingo.org/stream/2", ..., "id": 1}
Here is another example where we use Req to talk to two different servers. The first server
produces some test data, strings "foo", "bar" and "baz". The second one is an "echo" server, it simply
responds with the request body it returned. We then stream data from one server, transform it, and
stream it to the other one:
Mix.install([
  {:req, "~> 0.5"},
  {:bandit, "~> 1.0"}
])

{:ok, _} =
  Bandit.start_link(
    scheme: :http,
    port: 4000,
    plug: fn conn, _ ->
      conn = Plug.Conn.send_chunked(conn, 200)
      {:ok, conn} = Plug.Conn.chunk(conn, "foo")
      {:ok, conn} = Plug.Conn.chunk(conn, "bar")
      {:ok, conn} = Plug.Conn.chunk(conn, "baz")
      conn
    end
  )

{:ok, _} =
  Bandit.start_link(
    scheme: :http,
    port: 4001,
    plug: fn conn, _ ->
      {:ok, body, conn} = Plug.Conn.read_body(conn)
      Plug.Conn.send_resp(conn, 200, body)
    end
  )

resp = Req.get!("http://localhost:4000", into: :self)
stream = resp.body |> Stream.with_index() |> Stream.map(fn {data, idx} -> "[#{idx}]#{data}" end)
Req.put!("http://localhost:4001", body: stream).body
#=> "[0]foo[1]bar[2]baz"
Req.Response.Async is an experimental feature which may change in the future.
The existing caveats to into: :self still apply, that is:
	If the request is sent using HTTP/1, an extra process is spawned to consume messages from the
underlying socket.

	On both HTTP/1 and HTTP/2 the messages are sent to the current process as soon as they arrive,
as a firehose with no back-pressure.


If you wish to maximize request rate or have more control over how messages are streamed, use
into: fun or into: collectable instead.
Full v0.5.0 CHANGELOG
	Req: Deprecate setting :headers to values other than string/integer/DateTime.
This is to potentially allow special handling of atom values in the future.

	Req: Add Req.run/2 and Req.run!/2.

	Req: into: :self now sets response.body as Req.Response.Async which implements
enumerable.

	Req.Request: Deprecate setting :redact_auth. It now has no effect. Instead of allowing
to opt out of, we give an idea what the secret was without revealing it fully:
iex> Req.new(auth: {:basic, "foobar:baz"})
%Req.Request{
  options: %{auth: {:basic, "foo*******"}},
  ...
}

iex> Req.new(headers: [authorization: "bearer foobarbaz"])
%Req.Request{
  headers: %{"authorization" => ["bearer foo******"]},
  ...
}

	Req.Request: Deprecate halt/1 in favour of Req.Request.halt/2.

	Req.Test: Add Req.Test.transport_error/2 to simulate transport errors.

	Req.Test: Add Req.Test.expect/3.

	Req.Test: Add functions for setting ownership mode: Req.Test.set_req_test_from_context/1, Req.Test.set_req_test_to_private/1,
Req.Test.set_req_test_to_shared/1 and for verifying expectations: Req.Test.verify!/0, Req.Test.verify!/1, and Req.Test.verify_on_exit!/1.

	Req.Test: Add Req.Test.html/2.

	Req.Test: Add Req.Test.text/2.

	Req.Test: Drop :nimble_ownership dependency.

	Req.Test: Deprecate Req.Test.stub/1, i.e. the intended use case is to only work
with plug stubs/mocks.

	decode_body: Return Jason.DecodeError on JSON errors instead of raising it.

	decode_body: Return Req.ArchiveError on tar/zip errors.

	decompress_body: Return Req.DecompressError.

	put_aws_sigv4: Drop :aws_signature dependency.

	retry: (BREAKING CHANGE) Consider
%Req.TransportError{reason: :closed | :econnrefused | :timeout} as transient. Previously
any exceptions with those reason values were consider as such.

	retry: (BREAKING CHANGE) Consider
%Req.HTTPError{protocol: :http2, reason: :unprocessed} as transient.

	run_finch: (BREAKING CHANGE) Return Req.HTTPError instead of Mint.HTTPError.

	run_finch: (BREAKING CHANGE) Return Req.TransportError instead of Mint.TransportError.

	run_finch: Set inet6: true if URL looks like IPv6 address.

	put_plug: Move most documentation to run_plug.

	run_plug: Make public.

	run_plug: Add support for simulating network issues using Req.Test.transport_error/2.

	run_plug: Support passing 2-arity functions as plugs.

	run_plug: Automatically fetch query params.

	verify_checksum: Fix handling compressed responses.


v0.4.14 (2024-03-15)
	redirect: Return Req.TooManyRedirectsError exception.
Previously we always raised a RuntimeError. Besides changing the exception struct, now
it is returned:
iex> Req.get("https://httpbingo.org/redirect/4", max_redirects: 3)
# 07:08:06.868 [debug] redirecting to /relative-redirect/3
# 07:08:06.988 [debug] redirecting to /relative-redirect/2
# 07:08:07.109 [debug] redirecting to /relative-redirect/1
{:error, %Req.TooManyRedirectsError{max_redirects: 3}}
When users where using functions like Req.get!, the exception will of course still be
raised.

	Relax nimble_ownership version requirement

	Req.Test: Allow plug stub to be a module or {module, options}

	Req.Test: Document stubbing with Broadway


v0.4.13 (2024-03-07)
	run_finch: Default to connect_options: [protocols: [:http1]] due to regression
with HTTP/2 requests over HTTP/1 connections (protocols: [:http1, :http2]) with request body
size exceeding 64kib.

v0.4.12 (2024-03-06)
	Req: Add response body streaming via into: :self, Req.parse_message/2,
and Req.cancel_async_response/1.

	Req: Deprecate Req.update/2 in favour of Req.merge/2

	Req.Test: Add Req.Test.allow/3

	compressed: Default compressed: false when streaming response body

	put_base_url: Allow :base_url to be a 0-arity function or MFArgs

	put_plug: Do not leak Plug.Test messages


v0.4.11 (2024-02-19)
	Req.Test.json/2: Don't crash compilation when Plug is not available

v0.4.10 (2024-02-19)
	run_finch: Default to connect_options: [protocols: [:http1, :http2]].

	run_finch: Change version requirement to ~> 0.17, that is all versions up to 1.0.

	put_aws_sigv4: Support streaming request body.

	auth: Always update authorization header.

	decode_body: Gracefully handle multiple content-type values.

	Req.Request.new/1: Use URI.parse for now.


v0.4.9 (2024-02-14)
	retry: Raise on invalid return from :retry_delay function

	run_finch: Update to Finch 0.17

	run_finch: Deprecate connect_options: [protocol: ...] in favour of
connect_options: [protocols: ...]] which defaults to [:http1, :http2], that is,
make request using HTTP/1 but if negotiated switch to HTTP/2 over the HTTP/1 connection.

	New step: put_aws_sigv4 - signs request with AWS Signature Version 4.


v0.4.8 (2023-12-11)
	put_plug: Fix response streaming. Previously we were relying on unreleased
Plug features (which may never get released). Now, Plug adapter will emit the
entire response body as one chunk. Thus,
plug: plug, into: fn ... -> {:halt, acc} end is not yet supported as it
requires Plug changes that are still being discussed. On the flip side,
we should have much more stable Plug integration regardless of this small
limitation.

v0.4.7 (2023-12-11)
	put_plug: Don't crash if plug is not installed and :plug is not used

v0.4.6 (2023-12-11)
	New step: checksum
	put_plug: Fix response streaming when plug uses send_resp or send_file
	retry: Retry on :closed

v0.4.5 (2023-10-27)
	decompress_body: Remove content-length header

	auth: Deprecate auth: {user, pass} in favour of auth: {:basic, "user:pass"}

	Req.Request: Allow steps to be {mod, fun, args}


v0.4.4 (2023-10-05)
	compressed: Check for optional depenedencies brotli and ezstd only at compile-time.
(backported from v0.3.12.)

	decode_body: Check for optional depenedency nimble_csv at compile-time.
(backported from v0.3.12.)

	run_finch: Add :finch_private option


v0.4.3 (2023-09-13)
	Req.new/1: Fix setting :redact_auth

	Req.Request: Add Req.Request.get_option_lazy/3

	Req.Request: Add Req.Request.drop_options/2


v0.4.2 (2023-09-04)
	put_plug: Handle response streaming on Plug 1.15+.

	Don't warn on mixed-case header names


v0.4.1 (2023-09-01)
	Fix Req.Request Inspect regression

v0.4.0 (2023-09-01)
Req v0.4.0 changes headers to be maps, adds request & response streaming, and improves steps.
Change Headers to be Maps
Previously headers were lists of name/value tuples, e.g.:
[{"content-type", "text/html"}]
This is a standard across the ecosystem (with minor difference that some Erlang libraries use
charlists instead of binaries.)
There are some problems with this particular choice though:
	We cannot use headers[name]
	We cannot use pattern matching

In short, this representation isn't very ergonomic to use.
Now headers are maps of string names and lists of values, e.g.:
%{"content-type" => ["text/html"]}
This allows headers[name] usage:
response.headers["content-type"]
#=> ["text/html"]
and pattern matching:
case Req.request!(req) do
  %{headers: %{"content-type" => ["application/json" <> _]}} ->
    # handle JSON response
end
This is a major breaking change. If you cannot easily update your app
or your dependencies, do:
# config/config.exs
config :req, legacy_headers_as_lists: true
This legacy fallback will be removed on Req 1.0.
There are two other changes to headers in this release.
Header names are now case-insensitive in functions like
Req.Response.get_header/2.
Trailer headers, or more precisely trailer fields or simply trailers, are now stored
in a separate trailers field on the %Req.Response{} struct as long as you use Finch 0.17+.
Add Request Body Streaming
Req v0.4 adds official support for request body streaming by setting the request body to an
enumerable. Here's an example:
iex> stream = Stream.duplicate("foo", 3)
iex> Req.post!("https://httpbingo.org/post", body: stream).body["data"]
"foofoofoo"
The enumerable is passed through request steps and they may change it. For example,
the compress_body step gzips the request body on the fly.
Add Response Body Streaming
Req v0.4 also adds response body streaming, via the :into option.
Here's an example where we download the first 20kb (by making a range request, via the
put_range step) of Elixir release zip. We stream the response body into a function
and can handle each body chunk. The function receives a {:data, data}, {req, resp} and returns
a {:cont | :halt, {req, resp}} tuple.
resp =
  Req.get!(
    url: "https://github.com/elixir-lang/elixir/releases/download/v1.15.4/elixir-otp-26.zip",
    range: 0..20_000,
    into: fn {:data, data}, {req, resp} ->
      IO.inspect(byte_size(data), label: :chunk)
      {:cont, {req, resp}}
    end
  )

# output: 17:07:38.131 [debug] redirecting to https://objects.githubusercontent.com/github-production-release-asset-2e6(...)
# output: chunk: 16384
# output: chunk: 3617

resp.status #=> 206
resp.headers["content-range"] #=> ["bytes 0-20000/6801977"]
resp.body #=> ""
Notice we only stream response body, that is, Req automatically handles HTTP response status and
headers. Once the stream is done, Req passes the response through response steps which allows
following redirects, retrying on errors, etc. Response body is set to empty string ""
which is then ignored by decompress_body, decode_body, and similar steps. If you need
to decompress or decode incoming chunks, you need to do that in your custom into: fun function.
As the name :into implies, we can also stream response body into any Collectable.
Here's a similar snippet to above where we stream to a file:
resp =
  Req.get!(
    url: "https://github.com/elixir-lang/elixir/releases/download/v1.15.4/elixir-otp-26.zip",
    range: 0..20_000,
    into: File.stream!("elixit-otp-26.zip.1")
  )

# output: 17:07:38.131 [debug] redirecting to (...)
resp.status #=> 206
resp.headers["content-range"] #=> ["bytes 0-20000/6801977"]
resp.body #=> %File.Stream{}
Full CHANGELOG
	Change request.headers and response.headers to be maps.

	Ensure request.headers and response.headers are downcased.
Per RFC 9110: HTTP Semantics,
HTTP headers should be case-insensitive. However, per
RFC 9113: HTTP/2 headers
must be sent downcased.
Req headers are now stored internally downcased and all accessor functions
like Req.Response.get_header/2 are downcasing the given header name.

	Add trailers field to Req.Response struct. Trailer field is only filled in on Finch 0.17+.

	Make request.registered_options internal representation private.

	Make request.options internal representation private.
Currently request.options field is a map but it may change in the future.
One possible future change is using keywords lists internally which would
allow, for example, Req.new(params: [a: 1]) |> Req.merge(params: [b: 2])
to keep duplicate :params in request.options which would then allow to
decide the duplicate key semantics on a per-step basis. And so, for example,
put_params would merge params but most steps would simply use the
first value.
To have some room for manoeuvre in the future we should stop pattern
matching on request.options. Calling request.options[key],
put_in(request.options[key], value), and
update_in(request.options[key], fun) is allowed.

	Fix typespecs for some functions

	Deprecate output step in favour of into: File.stream!(path).

	Rename follow_redirects step to redirect

	redirect: Rename :follow_redirects option to :redirect.

	redirect: Rename :location_trusted option to :redirect_trusted.

	redirect: Change HTTP request method to GET only on POST requests that result in 301..303.
Previously we were changing the method to GET for all 3xx except 307 and 308.

	decompress_body: Remove support for deflate compression (which was broken)

	decompress_body: Don't crash on unknown codec

	decompress_body: Fix handling HEAD requests

	decompress_body: Re-calculate content-length header after decompresion

	decompress_body: Remove content-encoding header after decompression

	decode_body: Do not decode response with content-encoding header

	run_finch: Add :inet6 option

	retry: Support retry: :safe_transient which retries HTTP 408/429/500/502/503/504
or exceptions with reason field set to :timeout/:econnrefused.
:safe_transient is the new default retry mode. (Previously we retried on 408/429/5xx and
any exception.)

	retry: Support retry: :transient which is the same as :safe_transient except
it retries on all HTTP methods

	retry: Use retry-after header value on HTTP 503 Service Unavailable. Previously
only HTTP 429 Too Many Requests was using this header value.

	retry: Support retry: &fun/2. The function receives request, response_or_exception
and returns either:
	true - retry with the default delay

	{:delay, milliseconds} - retry with the given delay

	false/nil - don't retry



	retry: Deprecate retry: :safe in favour of retry: :safe_transient

	retry: Deprecate retry: :never in favour of retry: false

	Req.request/2: Improve error message on invalid arguments

	Req.merge/2: Do not duplicate headers

	Req.merge/2: Merge :params

	Req.Request: Fix displaying redacted basic authentication

	Req.Request: Add Req.Request.get_option/3

	Req.Request: Add Req.Request.fetch_option/2

	Req.Request: Add Req.Request.fetch_option!/2

	Req.Request: Add Req.Request.delete_option/2

	Req.Response: Add Req.Response.delete_header/2

	Req.Response: Add Req.Response.update_private/4


v0.3.12 (2023-08-05)
	compressed: Check for optional depenedencies brotli and ezstd only at compile-time.
	decode_body: Check for optional depenedency nimble_csv at compile-time.

v0.3.11 (2023-07-24)
	Support Req.get(options), Req.post(options), etc
	Add Req.Request.new/1
	retry: Fix returning correct private.req_retry_count

v0.3.10 (2023-06-20)
	decompress_body: No-op on non-binary response body
	decompress_body: Support multiple content-encoding headers
	decode_body: Remove :extract option
	Remove deprecated Req.post!(url, body) and similar functions

v0.3.9 (2023-06-08)
	put_path_params: URI-encode path params

v0.3.8 (2023-05-22)
	Add :redact_auth option to redact auth credentials, defaults to true.
	Soft-deprecate Req.Request.run,run! in favour of Req.Request.run_request/1.

v0.3.7 (2023-05-18)
	Deprecate setting headers to %NaiveDateTime{}, always use %DateTime{}.
	decode_body: Add :decode_json option
	[follow_redirects]: Add :redirect_log_level
	[follow_redirects]: Preserve HTTP method on 307/308 redirects
	run_finch: Allow :finch_request to perform the underlying request. This deprecates
passing 1-arity function f(finch_request) in favour of 4-arity
f(request, finch_request, finch_name, finch_options).

v0.3.6 (2023-03-06)
	run_finch: Fix setting :hostname option
	decode_body: Add :extract option to automatically extract archives (zip, tar, etc)

v0.3.5 (2023-02-01)
	New step: put_path_params
	auth: Accept string

v0.3.4 (2023-01-03)
	retry: Add :retry_log_level option

v0.3.3 (2022-12-08)
	[follow_redirects]: Inherit scheme from previous location
	run_finch: Fix setting connect timeout
	run_finch: Add :finch_request option

v0.3.2 (2022-11-14)
	decode_body: Decode JSON when response is json-api mime type
	put_params: Fix bug when params have been duplicated when retrying requeset
	retry: Remove retry: :always option
	retry: Soft-deprecate retry: :never in favour of retry: false
	run_finch: Add :transport_opts, :proxy_headers, :proxy, and :client_settings options
	Req.Response.json/2: Do not override content-type

v0.3.1 (2022-09-09)
	encode_body: Set Accept header in JSON requests
	put_base_url: Fix merging with leading and/or trailing slashes
	Fix merging :adapter option
	Add get/2, post/2, put/2, patch/2, delete/2 and head/2

v0.3.0 (2022-06-21)
Req v0.3.0 brings redesigned API, new steps, and improvements to existing steps.
New API
The new API allows building a request struct with all the built-in steps. It can be then piped
to functions like Req.get!/2:
iex> req = Req.new(base_url: "https://api.github.com")

iex> req |> Req.get!(url: "/repos/sneako/finch") |> then(& &1.body["description"])
"Elixir HTTP client, focused on performance"

iex> req |> Req.get(url: "/repos/elixir-mint/mint") |> then(& &1.body["description"])
"Functional HTTP client for Elixir with support for HTTP/1 and HTTP/2."
Setting body and encoding it to form/JSON is now done through :body/:form/:json options:
iex> Req.post!("https://httpbingo.org/anything", body: "hello!").body["data"]
"hello!"

iex> req = Req.new(url: "https://httpbingo.org/anything")
iex> Req.post!(req, form: [x: 1]).body["form"]
%{"x" => "1"}
iex> Req.post!(req, json: %{x: 2}).body["form"]
%{"x" => 2}
Improved Error Handling
Req now validates option names ensuring users didn't accidentally mistyped them.
If they did, it will try to give a helpful error message. Here are some examples:
Req.request!(urll: "https://httpbingo.org")
** (ArgumentError) unknown option :urll. Did you mean :url?

Req.new(bas_url: "https://httpbingo.org")
** (ArgumentError) unknown option :bas_url. Did you mean :base_url?
Req also has a new option to handle HTTP errors (4xx/5xx). By default it will continue to
return the error responses:
Req.get!("https://httpbingo.org/status/404")
#=> %Req.Response{status: 404, ...}
but users can now pass http_errors: :raise to raise an exception instead:
Req.get!("https://httpbingo.org/status/404", http_errors: :raise)
** (RuntimeError) The requested URL returned error: 404
Response body: ""
This is especially useful in one-off scripts where we only really care about the
"happy path" but would still like to get a good error message when something
unexpected happened.
Plugins
From the very beginning, Req could be extended with custom steps. To make using such custom steps
by others even easier, they can be packaged up into plugins.
Here are some examples:
	req_easyhtml
	req_s3
	req_hex
	req_github_oauth

And here's how they can be used:
Mix.install([
  {:req, "~> 0.3.0"},
  {:req_easyhtml, github: "wojtekmach/req_easyhtml"},
  {:req_s3, github: "wojtekmach/req_s3"},
  {:req_hex, github: "wojtekmach/req_hex"},
  {:req_github_oauth, github: "wojtekmach/req_github_oauth"}
])

req =
  (Req.new(http_errors: :raise)
  |> ReqEasyHTML.attach()
  |> ReqS3.attach()
  |> ReqHex.attach()
  |> ReqGitHubOAuth.attach())

Req.get!(req, url: "https://elixir-lang.org").body[".entry-summary h5"]
#=>
# #EasyHTML[<h5>
#    Elixir is a dynamic, functional language for building scalable and maintainable applications.
#  </h5>]

Req.get!(req, url: "s3://ossci-datasets").body
#=>
# [
#   "mnist/",
#   "mnist/t10k-images-idx3-ubyte.gz",
#   "mnist/t10k-labels-idx1-ubyte.gz",
#   "mnist/train-images-idx3-ubyte.gz",
#   "mnist/train-labels-idx1-ubyte.gz"
# ]

Req.get!(req, url: "https://repo.hex.pm/tarballs/req-0.1.0.tar").body["metadata.config"]["links"]
#=> %{"GitHub" => "https://github.com/wojtekmach/req"}

Req.get!(req, url: "https://api.github.com/user").body["login"]
# Outputs:
# paste this user code:
#
#   6C44-30A8
#
# at:
#
#   https://github.com/login/device
#
# open browser window? [Yn]
# 15:22:28.350 [info] response: authorization_pending
# 15:22:33.519 [info] response: authorization_pending
# 15:22:38.678 [info] response: authorization_pending
#=> "wojtekmach"

Req.get!(req, url: "https://api.github.com/user").body["login"]
#=> "wojtekmach"
Notice all plugins can be attached to the same request struct which makes it really easy to
explore different endpoints.
See "Writing Plugins" section in Req.Request module documentation
for more information.
Plug Integration
Req can now be used to easily test plugs using the :plug option:
defmodule Echo do
  def call(conn, _) do
    "/" <> path = conn.request_path
    Plug.Conn.send_resp(conn, 200, path)
  end
end

test "echo" do
  assert Req.get!("http:///hello", plug: Echo).body == "hello"
end
you can define plugs as functions too:
test "echo" do
  echo = fn conn ->
    "/" <> path = conn.request_path
    Plug.Conn.send_resp(conn, 200, path)
  end

  assert Req.get!("http:///hello", plug: echo).body == "hello"
end
which is particularly useful to create HTTP service mocks with tools like
Bypass.
Request Adapters
While Req always used Finch as the underlying HTTP client, it was designed from the day one to
easily swap it out. This is now even easier with an :adapter option.
Here is a mock adapter that always returns a successful response:
adapter = fn request ->
  response = %Req.Response{status: 200, body: "it works!"}
  {request, response}
end

Req.request!(url: "http://example", adapter: adapter).body
#=> "it works!"
Here is another one that uses the json/2 function to conveniently
return a JSON response:
adapter = fn request ->
  response = Req.Response.json(%{hello: 42})
  {request, response}
end

resp = Req.request!(url: "http://example", adapter: adapter)
resp.headers
#=> [{"content-type", "application/json"}]
resp.body
#=> %{"hello" => 42}
And here is a naive Hackney-based adapter and how we can use it:
hackney = fn request ->
  case :hackney.request(
         request.method,
         URI.to_string(request.url),
         request.headers,
         request.body,
         [:with_body]
       ) do
    {:ok, status, headers, body} ->
      headers = for {name, value} <- headers, do: {String.downcase(name), value}
      response = %Req.Response{status: status, headers: headers, body: body}
      {request, response}

    {:error, reason} ->
      {request, RuntimeError.exception(inspect(reason))}
  end
end

Req.get!("https://api.github.com/repos/elixir-lang/elixir", adapter: hackney).body["description"]
#=> "Elixir is a dynamic, functional language designed for building scalable and maintainable applications"
See "Adapter" section in Req.Request module documentation for more information.
Major changes
	Add high-level functional API: Req.new(...) |> Req.request(...), Req.new(...) |> Req.get!(...), etc.

	Add Req.Request.options field that steps can read from. Also, make
all steps be arity 1.
When using "High-level" API, we now run all steps by default. (The
steps, by looking at request.options, can decide to be no-op.)

	Move low-level API to Req.Request

	Move built-in steps to Req.Steps

	Add step names

	Add Req.head!/2

	Add Req.patch!/2

	Add Req.Request.adapter field

	Add Req.Request.merge_options/2

	Add Req.Request.register_options/2

	Add Req.Request.put_header/3

	Add Req.Request.put_headers/2

	Add Req.Request.put_new_header/3

	Add Req.Request.get_header/2

	Add Req.Request.update_private/4

	Add Req.Response.new/1

	Add Req.Response.json/2

	Add Req.Response.get_header/2

	Add Req.Response.put_header/3

	Rename put_if_modified_since step to cache

	Rename decompress step to decompress_body

	Remove put_default_steps step

	Remove run_steps step

	Remove put_default_headers step

	Remove encode_headers step. The headers are now encoded in Req.new/1 and Req.request/2

	Remove Req.Request.unix_socket field. Add option on run_finch step with the same name
instead.

	Require Elixir 1.12


Step changes
	New step: put_plug

	New step: put_user_agent (replaces part of removed put_default_headers)

	New step: compressed (replaces part of removed put_default_headers)

	New step: compress_body

	New step: [output]

	New step: handle_http_errors

	put_base_url: Ignore base URL if given URL contains scheme

	run_finch: Add :connect_options which dynamically starts (or re-uses already started)
Finch pool with the given connection options.

	run_finch: Replace :finch_options with :receive_timeout and :pool_timeout options

	encode_body: Add :form and :json options (previously used as {:form, data} and
{:json, data})

	cache: Include request method in cache key

	decompress_body, compressed: Support Brotli

	decompress_body, compressed: Support Zstandard

	decode_body: Support decode_body: false option to disable automatic body decoding

	[follow_redirects]: Change method to GET on 301..303 redirects

	[follow_redirects]: Don't send auth headers on redirect to different scheme/host/port
unless location_trusted: true is set

	retry: The Retry-After response header on HTTP 429 responses is now respected

	retry: The :retry option can now be set to :safe (default) to only retry GET/HEAD
requests on HTTP 408/429/5xx responses or exceptions, :always to always retry, :never to never
retry, and fun - a 1-arity function that accepts either a Req.Response or an exception
struct and returns boolean whether to retry

	retry: The :retry_delay option now accepts a function that takes a retry count (starting at 0)
and returns the delay. Defaults to a simple exponential backoff: 1s, 2s, 4s, 8s, ...


Deprecations
	Deprecate calling Req.post!(url, body) in favour of Req.post!(url, body: body).
Also, deprecate Req.post!(url, {:form, data}) in favour of Req.post!(url, form: data).
and Req.post!(url, {:json, data}) in favour of Req.post!(url, json: data). Same for
Req.put!/2.

	Deprecate setting retry: [delay: delay, max_retries: max_retries]
in favour of retry_delay: delay, max_retries: max_retries.

	Deprecate setting cache: [dir: dir] in favour of cache_dir: dir.

	Deprecate Req.build/3 in favour of manually building the struct.


v0.2.2 (2022-04-04)
	Relax Finch version requirement

v0.2.1 (2021-11-24)
	Add :private field to Response
	Update Finch to 0.9.1

v0.2.0 (2021-11-08)
	Rename normalize_headers to encode_headers
	Rename prepend_default_steps to put_default_steps
	Rename encode and decode to encode_body and decode_body
	Rename netrc to load_netrc
	Rename finch step to run_finch
	Rename if_modified_since to put_if_modified_since
	Rename range to put_range
	Rename params to put_params
	Rename request.uri to request.url
	Change response/error step contract from f(req, resp_err) to f({req, resp_err})
	Support mime 2.x
	Add Req.Response struct
	Add put!/3 and delete!/2
	Add run_steps/2
	Initial support for UNIX domain sockets
	Accept {module, args} and module as steps
	Ensure get_private and put_private have atom keys
	put_default_steps: Use MFArgs instead of captures for the default steps
	put_if_modified_since: Fix generating internet time
	encode_headers: Encode header values
	retry: Rename :max_attempts to :max_retries

v0.1.1 (2021-07-16)
	Fix append_request_steps/2 and prepend_request_steps/2 (they did the opposite)
	Add finch/1

v0.1.0 (2021-07-15)
	Initial release

The high-level API.
Req is composed of:
	Req - the high-level API (you're here!)

	Req.Request - the low-level API and the request struct

	Req.Auth, …, Req.Steps - a collection of built-in steps.

	Req.Test - the testing conveniences


The high-level API is what most users of Req will use most of the time.
Examples
Making a GET request with Req.get!/1:
iex> Req.get!("https://api.github.com/repos/wojtekmach/req").body["description"]
"Req is a batteries-included HTTP client for Elixir."
Same, but by explicitly building request struct first:
iex> req = Req.new(base_url: "https://api.github.com")
iex> Req.get!(req, url: "/repos/wojtekmach/req").body["description"]
"Req is a batteries-included HTTP client for Elixir."
The request that was sent is available in resp.request:
iex> resp = Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: {:basic, "foo:bar"})
iex> resp.request.headers["authorization"]
["Basic Zm9vOmJhcg=="]
iex> resp.status
200
Making a POST request with Req.post!/2:
iex> Req.post!("https://httpbingo.org/post", form: [comments: "hello!"]).body["form"]
%{"comments" => ["hello!"]}
Set connection timeout:
iex> resp = Req.get!("https://httpbingo.org", connect_options: [timeout: 100])
iex> resp.status
200
See Req.Finch for more connection related options and usage examples.
Stream request body:
iex> stream = Stream.duplicate("foo", 3)
iex> Req.post!("https://httpbingo.org/post", body: stream, headers: [content_type: "text/plain"]).body["data"]
"foofoofoo"
Stream response body using Req.stream/4:
iex> {:ok, resp, acc} =
...> Req.stream(
...>   "http://httpbingo.org/stream/2",
...>   [],
...>   fn data, _resp, acc ->
...>     IO.inspect(data)
...>     {:cont, acc}
...>   end,
...>   decoders: [text: :ndjson] # endpoint sends content-type: text/plain
...>                             # so let's force ndjson.
...> )
# Output: %{"id" => 0, ...}
# Output: %{"id" => 1, ...}
iex> resp.status
200
iex> resp.body
nil
Stream response body into a Collectable:
iex> resp = Req.get!("http://httpbingo.org/stream/2", into: IO.stream())
# output: {"url": "http://httpbingo.org/stream/2", ...}
# output: {"url": "http://httpbingo.org/stream/2", ...}
iex> resp.status
200
iex> resp.body
%IO.Stream{}
Stream response body to the current process and parse incoming messages using Req.parse_message/2.
iex> resp = Req.get!("http://httpbingo.org/stream/2", into: :self)
iex> Req.parse_message(resp, receive do message -> message end)
{:ok, [data: "{\"url\": \"http://httpbingo.org/stream/2\", ..., \"id\": 0}\n"]}
iex> Req.parse_message(resp, receive do message -> message end)
{:ok, [data: "{\"url\": \"http://httpbingo.org/stream/2\", ..., \"id\": 1}\n"]}
iex> Req.parse_message(resp, receive do message -> message end)
{:ok, [:done]}
""
Same as above, using enumerable API:
iex> resp = Req.get!("http://httpbingo.org/stream/2", into: :self)
iex> resp.body
#Req.Response.Async<...>
iex> Enum.each(resp.body, &IO.puts/1)
# {"url": "http://httpbingo.org/stream/2", ..., "id": 0}
# {"url": "http://httpbingo.org/stream/2", ..., "id": 1}
:ok
See :into option in Req.new/1 documentation for more information on response body streaming.
Headers
The HTTP specification requires that header names should be case-insensitive.
Req allows two ways to access the headers; using functions and by accessing
the data directly:
iex> Req.Response.get_header(response, "content-type")
["text/html"]

iex> response.headers["content-type"]
["text/html"]
While we can ensure case-insensitive handling in the former case, we can't
in the latter. For this reason, Req made the following design choices:
	header names are stored as downcased

	functions like Req.Request.get_header/2, Req.Request.put_header/3,
Req.Response.get_header/2, Req.Response.put_header/3, etc
automatically downcase the given header name.


Note
Most Elixir/Erlang HTTP clients represent headers as lists of tuples like:
[{"content-type", "text/plain"}]
For interoperability with those, use
Req.get_headers_list/1.

          @spec default_options() :: keyword()


      


Returns default options.
See default_options/1 for more information.

          @spec default_options(keyword()) :: :ok


      


Sets default options for Req.new/1.
Avoid setting default options in libraries as they are global.
Examples
iex> Req.default_options(base_url: "https://httpbingo.org")
iex> Req.get!("/statuses/201").status
201
iex> Req.new() |> Req.get!(url: "/statuses/201").status
201

  



  
    
      
    
    
      get_headers_list(struct)


        (since 0.5.10)


        
          
        

    

  


  

      

          @spec get_headers_list(Req.Request.t() | Req.Response.t()) :: [{binary(), binary()}]


      


Returns request/response headers as list.
Examples
iex> req = Req.Request.new(headers: %{"accept" => ["application/json"]})
iex> Req.get_headers_list(req)
[{"accept", "application/json"}]

iex> resp = Req.Response.new(headers: %{"content-type" => ["application/json"]})
iex> Req.get_headers_list(resp)
[{"content-type", "application/json"}]

          @spec merge(Req.Request.t(), options :: keyword()) :: Req.Request.t()


      


Updates a request struct.
See new/1 for a list of available options. Also see Req.Request module documentation
for more information on the underlying request struct.
Examples
iex> req = Req.new(base_url: "https://httpbingo.org")
iex> req = Req.merge(req, auth: {:basic, "alice:secret"})
iex> req.options[:base_url]
"https://httpbingo.org"
iex> req.options[:auth]
{:basic, "alice:secret"}
Passing :headers will automatically encode and merge them:
iex> req = Req.new(headers: %{point_x: 1})
iex> req = Req.merge(req, headers: %{point_y: 2})
iex> req.headers
%{"point-x" => ["1"], "point-y" => ["2"]}
The same header names are overwritten however:
iex> req = Req.new(headers: %{authorization: "bearer foo"})
iex> req = Req.merge(req, headers: %{authorization: "bearer bar"})
iex> req.headers
%{"authorization" => ["bearer bar"]}
Similarly to headers, :params are merged too:
req = Req.new(url: "https://httpbingo.org/anything", params: [a: 1, b: 1])
req = Req.merge(req, params: [a: 2])
Req.get!(req).body["args"]
#=> %{"a" => ["2"], "b" => ["1"]}

          @spec new(request :: url() | keyword() | Req.Request.t(), options :: keyword()) ::
  Req.Request.t()


      


Returns a new request struct with built-in steps.
See request/2, as well as get/2, post/2, and similar functions for
making requests.
Also see Req.Request module documentation for more information on the underlying request
struct.
Options
Basic request options:
	:method - the request method, defaults to :get.

	:url - the request URL.

	:headers - the request headers as a {key, value} enumerable (e.g. map, keyword list).
The header names should be downcased.
The headers are automatically encoded using these rules:
	atom header names are turned into strings, replacing _ with -. For example,
:user_agent becomes "user-agent".

	string header names are downcased.

	%DateTime{} header values are encoded as "HTTP date".


If you set :headers options both in Req.new/1 and request/2, the header lists are merged.
See also "Headers" section in the module documentation.

	:body - the request body.
Can be one of:
	nil - no body is sent with the request.

	iodata - request body as "IO data".

	enumerable - stream request body chunks emitted by the given Enumerable.

	req_body_fun - stream request body chunks from a 1-arity function.
Only supported in Req.stream/4.
The function receives the accumulator passed to Req.stream/4 and should
return one of:
	{:data, chunk, acc} - Emit request body chunk and continue streaming.

	{:done, chunk, acc} - emit the final request body chunk. acc is passed to the
response streaming function.

	{:done, acc} - request body streaming is done. acc is passed to the
response streaming function.

	{:halt, acc} - cancel request. On HTTP/1, this closes the connection.

	{:error, exception, acc} - cancel request and return {:error, exception, resp, acc}
from Req.stream/4.





	:private - a map reserved for libraries and frameworks to use. The keys must be atoms.


Additional URL options:
	:base_url - if set, the request URL is prepended with this base URL (via
put_base_url step.)

	:params - if set, appends parameters to the request query string (via
put_params step.)

	:path_params - if set, uses a templated request path (via
put_path_params step.)

	:path_params_style (available since v0.5.1) - how path params are expressed (via
put_path_params step). Can be one of:
	:colon - (default) for Plug-style parameters, such as :code in
https://httpbingo.org/status/:code.

	:curly - for OpenAPI-style parameters, such as
{code} in https://httpbingo.org/status/{code}.




Authentication options:
	:auth - sets request authentication (via Req.Auth step.)
Can be one of:
	{:basic, userinfo} - uses Basic HTTP authentication.

	{:digest, userinfo} - uses Digest HTTP authentication.

	{:bearer, token} - uses Bearer HTTP authentication.

	:netrc - load credentials from the default .netrc file.

	{:netrc, path} - load credentials from path.

	string - sets to this value.

	&fun/0 - a function that returns one of the above (such as a {:bearer, token}).

	{mod, fun, args} - an MFArgs tuple that returns one of the above (such as a {:bearer, token}).




Request body encoding options (encode_body):
	:form - if set, encodes the request body as application/x-www-form-urlencoded

	:form_multipart - if set, encodes the request body as multipart/form-data.

	:json - if set, encodes the request body as JSON


Other request body options:
	:compress_body - if set to true, compresses the request body using gzip (via compress_body step.)
Defaults to false.

Other request options:
	:user_agent - sets the user-agent request header, see Req.Steps.put_user_agent/1.

	:range - sets the range request header, see Req.Steps.put_range/1.


AWS Signature Version 4 options (put_aws_sigv4 step):
	:aws_sigv4 - if set, the AWS options to sign request:
	:access_key_id - the AWS access key id.

	:secret_access_key - the AWS secret access key.

	:service - the AWS service.

	:region - if set, AWS region. Defaults to "us-east-1".

	:datetime - the request datetime, defaults to DateTime.utc_now(:second).




Response body options:
	:compressed - if set to true, asks the server to return a compressed response and
decompresses it. Defaults to false.
Note: the response body is decompressed with no size limit, so a small response can
expand into many gigabytes. A malicious or compromised server can exploit this to
exhaust memory and crash the client (a decompression bomb / denial of service), so
only set compressed: true for endpoints you trust.

	:raw - if set to true, disables body decompression and automatic decoding
(see Req.Decompress and Req.Decode). Defaults to false.

	:decode_body - if set to false, disables automatic response body decoding.
Defaults to true.

	:decoders - the list of decoders to use for automatic response body decoding.
Defaults to [:json, :json_api, :ndjson, :sse]. See Req.Decode for the supported
formats and how to add custom decoders.

	:into - where to send the response body. It can be one of:
	nil - (default) read the whole response body and store it in the response.body
field.

	collectable - stream response body into a Collectable.t/0. For example:
 into: File.stream!("path")
Note that the collectable is only used, if the response status is 200. In other cases,
the body is accumulated and processed as usual.

	:self - stream response body into the current process mailbox.
Received messages should be parsed with Req.parse_message/2.
response.body is set to opaque data structure Req.Response.Async which implements
Enumerable that receives and automatically parses messages. See module documentation
for example usage.
If the request is sent using HTTP/1, an extra process is spawned to consume messages
from the underlying socket. On both HTTP/1 and HTTP/2 the messages are sent to the
current process as soon as they arrive, as a firehose. If you wish to maximize request
rate or have more control over how messages are streamed, use Req.stream/4 or
into: collectable instead.


Note: Req.stream/4 does not support :into option.


Response redirect options (Req.Redirect step):
	:redirect - if set to false, disables automatic response redirects. Defaults to true.

	:redirect_trusted - by default, authorization credentials are only sent on redirects
with the same host, scheme and port. If :redirect_trusted is set to true, credentials
will be sent to any host. Defaults to false.

	:redirect_log_level - the log level to emit redirect logs at. Can also be set
to false to disable logging these messages. Defaults to :debug.

	:max_redirects - the maximum number of redirects, defaults to 10.


Other response options:
	:expect - the expected HTTP response status (via Req.Expect step).
Can be an integer, a range, or a list of integers/ranges.

	:checksum - if set, this is the expected response body checksum, see Req.Checksum.


Retry options (Req.Retry step):
	:retry - can be one of the following:
	:safe_transient (default) - retry safe (GET/HEAD) requests on one of:
	HTTP 408/429/500/502/503/504 responses

	Req.TransportError with reason: :timeout | :econnrefused | :closed

	Req.HTTPError with
protocol: :http2, reason: :unprocessed | :pool_not_available



	:transient - same as :safe_transient except retries all HTTP methods (POST, DELETE, etc.)

	fun - a 2-arity function that accepts a Req.Request and either a Req.Response or an exception struct
and returns one of the following:
	true - retry using the default delay described under :retry_delay below.

	{:delay, milliseconds} - retry with the given delay.

	false/nil - don't retry.



	false - don't retry.



	:retry_delay - if not set, which is the default, the retry delay is determined by
the value of the Retry-After header on HTTP 429/503 responses. If the header is not set,
the default delay follows a simple exponential backoff with jitter, for example:
0.949s, 1.97s, 3.87s, 7.55s, ...
:retry_delay can be set to a function that receives the retry count (starting at 0)
and returns the delay, the number of milliseconds to sleep before making another attempt.

	:retry_log_level - the log level to emit retry logs at. Can also be set to false to disable
logging these messages. Defaults to :warning.

	:max_retries - maximum number of retry attempts, defaults to 3 (for a total of 4
requests to the server, including the initial one.)


Request adapters:
	:adapter - adapter to use to make the actual HTTP request. See :adapter field description
in the Req.Request module documentation for more information.
The default is Req.Finch.

	:plug - if set, calls the given plug instead of making an HTTP request over the network (via the Req.Plug adapter).
The plug can be one of:
	A function plug: a fun(conn) or fun(conn, options) function that takes a
Plug.Conn and returns a Plug.Conn.

	A module plug: a module name or a {module, options} tuple.




Finch options (Req.Finch adapter), see Finch.start_link/1 for options:
	:finch - options for the Finch adapter. Defaults to a pool automatically started by
Req. Can include:
	:name - the name of the Finch pool.

	Finch request options, e.g. :pool_tag, :pool_timeout, :receive_timeout. See
Finch.Request.build_opt/0 and Finch.request_opt/0 for more information.

	Finch pool options, e.g.: :conn_max_idle_time, :pool_max_idle_time, :conn_opts.
See Finch.start_link/1 for more information.
Finch pool options cannot be mixed with :name option.


Examples:
Req.get!("https://httpbingo.org/json", finch: [name: MyFinch])
Req.get!("https://httpbingo.org/json", finch: [name: MyFinch, pool_tag: :bulk])
Req.get!("https://httpbingo.org/json", finch: [conn_max_idle_time: 10_000])

	:connect_options - dynamically starts (or re-uses already started) Finch pool with
the given connection options (see Mint.HTTP.connect/4 for options):
	:timeout - socket connect timeout in milliseconds, defaults to 30_000.

	:protocols - the HTTP protocols to use, defaults to
[:http1].

	:hostname - Mint explicit hostname.

	:transport_opts - Mint transport options.

	:proxy_headers - Mint proxy headers.

	:proxy - Mint HTTP/1 proxy settings, a {scheme, address, port, options} tuple.

	:client_settings - Mint HTTP/2 client settings.



	:inet6 - if set to true, uses IPv6. Defaults to false.

	:receive_timeout - socket receive timeout in milliseconds, defaults to 15_000.

	:request_timeout - response timeout in milliseconds, defaults to :infinity.
See Finch.request/3.

	:unix_socket - if set, connect through the given UNIX domain socket.

	:finch_private - a map or keyword list of private metadata to add to the Finch request. May be useful
for adding custom data when handling telemetry with Finch.Telemetry.


Examples
iex> req = Req.new(url: "https://elixir-lang.org")
iex> req.method
:get
iex> URI.to_string(req.url)
"https://elixir-lang.org"
With a url and options:
iex> req = Req.new("https://elixir-lang.org", method: :head)
iex> req.method
:head

          @spec delete(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  {:ok, Req.Response.t()} | {:error, Exception.t()}


      


Makes a DELETE request and returns a response or an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> {:ok, resp} = Req.delete("https://httpbingo.org/anything")
iex> resp.body["method"]
"DELETE"
With options:
iex> {:ok, resp} = Req.delete(url: "https://httpbingo.org/anything")
iex> resp.body["method"]
"DELETE"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> {:ok, resp} = Req.delete(req)
iex> resp.body["method"]
"DELETE"

  



    

  
    
      
    
    
      delete!(request, options \\ [])



        
          
        

    

  


  

      

          @spec delete!(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  Req.Response.t()


      


Makes a DELETE request and returns a response or raises an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> Req.delete!("https://httpbingo.org/anything").body["method"]
"DELETE"
With options:
iex> Req.delete!(url: "https://httpbingo.org/anything").body["method"]
"DELETE"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> Req.delete!(req).body["method"]
"DELETE"

          @spec get(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  {:ok, Req.Response.t()} | {:error, Exception.t()}


      


Makes a GET request and returns a response or an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> {:ok, resp} = Req.get("https://api.github.com/repos/wojtekmach/req")
iex> resp.body["description"]
"Req is a batteries-included HTTP client for Elixir."
With options:
iex> {:ok, resp} = Req.get(url: "https://api.github.com/repos/wojtekmach/req")
iex> resp.status
200
With request struct:
iex> req = Req.new(base_url: "https://api.github.com")
iex> {:ok, resp} = Req.get(req, url: "/repos/elixir-lang/elixir")
iex> resp.status
200

  



    

  
    
      
    
    
      get!(request, options \\ [])



        
          
        

    

  


  

      

          @spec get!(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  Req.Response.t()


      


Makes a GET request and returns a response or raises an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> Req.get!("https://api.github.com/repos/wojtekmach/req").body["description"]
"Req is a batteries-included HTTP client for Elixir."
With options:
iex> Req.get!(url: "https://api.github.com/repos/wojtekmach/req").status
200
With request struct:
iex> req = Req.new(base_url: "https://api.github.com")
iex> Req.get!(req, url: "/repos/elixir-lang/elixir").status
200

  



    

  
    
      
    
    
      head(request, options \\ [])



        
          
        

    

  


  

      

          @spec head(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  {:ok, Req.Response.t()} | {:error, Exception.t()}


      


Makes a HEAD request and returns a response or an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> {:ok, resp} = Req.head("https://httpbingo.org/status/201")
iex> resp.status
201
With options:
iex> {:ok, resp} = Req.head(url: "https://httpbingo.org/status/201")
iex> resp.status
201
With request struct:
iex> req = Req.new(base_url: "https://httpbingo.org")
iex> {:ok, resp} = Req.head(req, url: "/status/201")
iex> resp.status
201

  



    

  
    
      
    
    
      head!(request, options \\ [])



        
          
        

    

  


  

      

          @spec head!(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  Req.Response.t()


      


Makes a HEAD request and returns a response or raises an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> Req.head!("https://httpbingo.org/status/201").status
201
With options:
iex> Req.head!(url: "https://httpbingo.org/status/201").status
201
With request struct:
iex> req = Req.new(base_url: "https://httpbingo.org")
iex> Req.head!(req, url: "/status/201").status
201

  



    

  
    
      
    
    
      patch(request, options \\ [])



        
          
        

    

  


  

      

          @spec patch(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  {:ok, Req.Response.t()} | {:error, Exception.t()}


      


Makes a PATCH request and returns a response or an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> {:ok, resp} = Req.patch("https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"])
iex> resp.body["data"]
"hello!"
With options:
iex> {:ok, resp} = Req.patch(url: "https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"])
iex> resp.body["data"]
"hello!"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> {:ok, resp} = Req.patch(req, body: "hello!")
iex> resp.body["data"]
"hello!"

  



    

  
    
      
    
    
      patch!(request, options \\ [])



        
          
        

    

  


  

      

          @spec patch!(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  Req.Response.t()


      


Makes a PATCH request and returns a response or raises an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> Req.patch!("https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"]).body["data"]
"hello!"
With options:
iex> Req.patch!(url: "https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"]).body["data"]
"hello!"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> Req.patch!(req, body: "hello!").body["data"]
"hello!"

  



    

  
    
      
    
    
      post(request, options \\ [])



        
          
        

    

  


  

      

          @spec post(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  {:ok, Req.Response.t()} | {:error, Exception.t()}


      


Makes a POST request and returns a response or an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> {:ok, resp} =
...>   Req.post(
...>     "https://httpbingo.org/anything",
...>     body: "hello!",
...>     headers: [content_type: "text/plain"]
...>   )
iex> resp.body["data"]
"hello!"

iex> {:ok, resp} = Req.post("https://httpbingo.org/anything", form: [x: 1])
iex> resp.body["form"]
%{"x" => ["1"]}

iex> {:ok, resp} = Req.post("https://httpbingo.org/anything", json: %{x: 2})
iex> resp.body["json"]
%{"x" => 2}
With options:
iex> {:ok, resp} = Req.post(url: "https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"])
iex> resp.body["data"]
"hello!"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> {:ok, resp} = Req.post(req, body: "hello!")
iex> resp.body["data"]
"hello!"

  



    

  
    
      
    
    
      post!(request, options \\ [])



        
          
        

    

  


  

      

          @spec post!(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  Req.Response.t()


      


Makes a POST request and returns a response or raises an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> Req.post!("https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"]).body["data"]
"hello!"

iex> Req.post!("https://httpbingo.org/anything", form: [x: 1]).body["form"]
%{"x" => ["1"]}

iex> Req.post!("https://httpbingo.org/anything", json: %{x: 2}).body["json"]
%{"x" => 2}
With options:
iex> Req.post!(url: "https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"]).body["data"]
"hello!"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> Req.post!(req, body: "hello!").body["data"]
"hello!"

  



    

  
    
      
    
    
      put(request, options \\ [])



        
          
        

    

  


  

      

          @spec put(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  {:ok, Req.Response.t()} | {:error, Exception.t()}


      


Makes a PUT request and returns a response or an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> {:ok, resp} = Req.put("https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"])
iex> resp.body["data"]
"hello!"
With options:
iex> {:ok, resp} = Req.put(url: "https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"])
iex> resp.body["data"]
"hello!"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> {:ok, resp} = Req.put(req, body: "hello!")
iex> resp.body["data"]
"hello!"

  



    

  
    
      
    
    
      put!(request, options \\ [])



        
          
        

    

  


  

      

          @spec put!(url() | keyword() | Req.Request.t(), options :: keyword()) ::
  Req.Response.t()


      


Makes a PUT request and returns a response or raises an error.
request can be one of:
	an url (String or URI);

	a Keyword options;

	a Req.Request struct


See new/1 for a list of available options.
Examples
With URL:
iex> Req.put!("https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"]).body["data"]
"hello!"
With options:
iex> Req.put!(url: "https://httpbingo.org/anything", body: "hello!", headers: [content_type: "text/plain"]).body["data"]
"hello!"
With request struct:
iex> req = Req.new(url: "https://httpbingo.org/anything", headers: [content_type: "text/plain"])
iex> Req.put!(req, body: "hello!").body["data"]
"hello!"

          @spec request(request :: Req.Request.t() | keyword(), options :: keyword()) ::
  {:ok, Req.Response.t()} | {:error, Exception.t()}


      


Makes an HTTP request and returns a response or an error.
request can be one of:
	a Keyword options;
	a Req.Request struct

See new/1 for a list of available options.
Examples
With options keywords list:
iex> {:ok, response} = Req.request(url: "https://api.github.com/repos/wojtekmach/req")
iex> response.status
200
iex> response.body["description"]
"Req is a batteries-included HTTP client for Elixir."
With request struct:
iex> req = Req.new(url: "https://api.github.com/repos/elixir-lang/elixir")
iex> {:ok, response} = Req.request(req)
iex> response.status
200

  



    

  
    
      
    
    
      request!(request, options \\ [])



        
          
        

    

  


  

      

          @spec request!(request :: Req.Request.t() | keyword(), options :: keyword()) ::
  Req.Response.t()


      


Makes an HTTP request and returns a response or raises an error.
See new/1 for a list of available options.
Examples
With options keywords list:
iex> Req.request!(url: "https://api.github.com/repos/elixir-lang/elixir").status
200
With request struct:
iex> req = Req.new(url: "https://api.github.com/repos/elixir-lang/elixir")
iex> Req.request!(req).status
200

  



    

  
    
      
    
    
      stream(req, acc, fun, options \\ [])



        
          
        

    

  


  

      

          @spec stream(req, acc, fun, options) :: {:ok, resp, acc} | {:error, err, resp, acc}
when req: url() | keyword() | Req.Request.t(),
     resp: Req.Response.t(),
     err: Exception.t(),
     acc: term(),
     fun: (data :: term(), resp, acc -> {:cont, acc} | {:halt, acc}),
     options: keyword()


      


Streams an HTTP request.
req can be one of:
	an url (String or URI);
	a Keyword options;
	a Req.Request struct

acc is the initial accumulator. fun receives response body chunk, the response struct, and
accumulator. fun must return {:cont, acc} to continue streaming or {:halt, acc} to cancel
the request (on HTTP/1 cancelling the request closes the connection):
fn data, resp, acc ->
  {:cont, acc} | {:halt, acc}
end
data is automatically decoded for some formats, including NDJSON and SSE (Server-Sent Events).
See Req.Decode for more information.
Req.stream/4 returns {:ok, resp, acc} or {:error, err, resp, acc}.
See new/1 for a list of available options.
Examples
Returns recent Wikipedia changes:
iex> {:ok, resp, acc} =
...>   Req.stream(
...>     "https://stream.wikimedia.org/v2/stream/recentchange",
...>     [],
...>     fn event, _resp, acc ->
...>       %{"type" => type, "title" => title} = JSON.decode!(event.data)
...>       event = {type, title}
...> 
...>       if length(acc) < 1 do
...>         {:cont, [event | acc]}
...>       else
...>         {:halt, [event | acc]}
...>       end
...>     end
...>   )
iex> resp.status
200
iex> resp.body
nil
iex> Enum.reverse(acc)
[
  {"edit", "File:Glacier National Park (GeoDIL number - 2068).jpg"},
  {"categorize", "Category:Coins of Merovingian dynasty from Gallica"}
]
Returns an error:
iex> {:error, err, resp, acc} =
...>   Req.stream(
...>     "http://localhost:9999",
...>     nil,
...>     fn data, _resp, acc -> dbg(data); {:cont, acc} end,
...>     retry: false
...>   )
iex> err
%Req.TransportError{reason: :econnrefused}
iex> resp.status
nil
iex> to_string(resp.request.url)
"http://localhost:9999"

  


        

      

      
        Functions (Async Response)


        


  
    
      
    
    
      cancel_async_response(response)



        
          
        

    

  


  

Cancels an asynchronous response.
An asynchronous response is a result of request with into: :self.
See also Req.Response.Async.
Examples
iex> resp = Req.get!("http://httpbingo.org/stream/2", into: :self)
iex> Req.cancel_async_response(resp)
:ok

Parses asynchronous response body message.
A request with option :into set to :self returns response with asynchronous body.
In that case, Req sends chunks to the calling process as messages. You'd typically
get them using receive/1 or handle_info/2 in a GenServer.
These messages should be parsed using this function. The possible return values are:
	{:ok, chunks} - where a chunk can be {:data, binary}, {:trailers, trailers}, or
:done.

	{:error, reason} - an error occurred

	:unknown - the message was not meant for this response.


See also Req.Response.Async.
Examples
iex> resp = Req.get!("http://httpbingo.org/stream/2", into: :self)
iex> Req.parse_message(resp, receive do message -> message end)
{:ok, [data: "{"url": "http://httpbingo.org/stream/2", ..., "id": 0}\n"]}
iex> Req.parse_message(resp, receive do message -> message end)
{:ok, [data: "{"url": "http://httpbingo.org/stream/2", ..., "id": 1}\n"]}
iex> Req.parse_message(resp, receive do message -> message end)
{:ok, [:done]}
iex> Req.parse_message(resp, :other)
:unknown

The low-level API and the request struct.
Req is composed of:
	Req - the high-level API

	Req.Request - the low-level API and the request struct (you're here!)

	Req.Auth, …, Req.Steps - a collection of built-in steps.

	Req.Test - the testing conveniences


The low-level API and the request struct is the foundation of Req's extensibility. Virtually all
of the functionality is broken down into individual pieces - steps. See
"Steps & Step Wrappers" section for more information.
To make using custom steps by others even easier, they can be packaged up into plugins.
See "Writing Plugins" section for more information.
The Request Struct
Public fields are:
	:method - the HTTP request method.

	:url - the HTTP request URL.

	:headers - the HTTP request headers. The header names should be downcased.
See also "Headers" section in Req module documentation.

	:body - the HTTP request body.
Can be one of:
	iodata - eagerly send request body

	enumerable - stream request body

	req_body_fun - stream request body chunks from a 1-arity function.
Only supported in Req.stream/4. The function receives the accumulator
passed to Req.stream/4.
It should return one of:
	{:data, chunk, acc} - emit request body chunk.

	{:done, chunk, acc} - emit the final request body chunk. acc is passed to the
response streaming function.

	{:done, acc} - request body is done. acc is passed to the response
streaming function.

	{:halt, acc} - cancel request. On HTTP/1, this closes the connection.

	{:error, exception, acc} - cancel request and return {:error, exception, resp, acc}
from Req.stream/4.





	:into - where to send the response body. It can be one of:
	nil - (default) read the whole response body and store it in the response.body
field.

	collectable - stream response body into a Collectable.t/0. For example:
into: File.stream!("path")
Note that the collectable is only used, if the response status is 200. In other cases,
the body is accumulated and processed as usual.

	:self - stream response body into the current process mailbox. The response body is
set to a Req.Response.Async struct that consumes the messages.


Note: Req.stream/4 does not support :into option.

	:options - the options to be used by steps. The exact representation of options is private.
Calling request.options[key], put_in(request.options[key], value), and
update_in(request.options[key], fun) is allowed. get_option/3 and delete_option/2
are also available for additional ways to manipulate the internal representation.

	:halted - whether the request pipeline is halted. See halt/2.

	:adapter - the adapter that makes the actual HTTP request. Defaults to Req.Finch.

	:request_steps - the list of request steps

	:private - a map reserved for libraries and frameworks to use.
The keys must be atoms. Prefix the keys with the name of your project
to avoid any future conflicts. The req_ prefix is reserved for Req.


The Low-level API
Most Req users would use it like this:
Req.get!("https://api.github.com/repos/wojtekmach/req").body["description"]
#=> "Req is a batteries-included HTTP client for Elixir."
Here is the equivalent using the low-level API:
req =
  Req.Request.new(
    url: "https://api.github.com/repos/wojtekmach/req"
  )
  |> Req.Request.register_options(
    # ...
    :decoders,
    # ...
  )
  |> Req.Request.prepend_request_steps(
    # ...
    decode: Req.Decode,
    # ...
  )

Req.get!(req).body["description"]
#=> "Req is a batteries-included HTTP client for Elixir."
In other words, Req.new/1, Req.get/1, and friends start with all the built-in steps and
options but Req.Request.new/1 starts with a blank slate!
Steps & Step Wrappers
The simplest building blocks are steps, functions that take and return a request. For example:
defmodule MyApp do
  def put_user_agent(%Req.Request{} = req) do
    if user_agent = req.options[:user_agent] do
      Req.Request.put_header(req, "user-agent", user_agent)
    else
      req
    end
  end
end

req =
  Req.Request.new()
  |> Req.Request.register_options([:user_agent])
  |> Req.Request.prepend_request_steps(
    put_user_agent: &MyApp.put_user_agent/1,
  )

resp =
  Req.get!(
    req,
    url: "https://httpbingo.org/user-agent",
    user_agent: "foo"
  )

JSON.decode!(resp.body)      # We used Req.Request.new() so we're not using built-in decoding.
#=> %{"user-agent" => "foo"}
Next up, we have step wrappers, they additionally take acc, fun, state, and next.
next is a function representing the rest of the processing pipeline, including hitting the
network.
The simplest possible wrapper just calls the next one:
fn req, acc, fun, state, next ->
  next.(req, acc, fun, state)
end
Here's another example:
defmodule MyApp do
  def expect_successful(req, acc, fun, state, next) do
    fun = fn
      {:status, status}, resp, acc, state when status in 200..299 ->
        fun.({:status, status}, resp, acc, state)

      {:status, status}, resp, acc, state ->
        err = RuntimeError.exception("unexpected status #{status}")
        {{:error, err}, resp, acc, state}

      event, resp, acc, state ->
        fun.(event, resp, acc, state)
    end

    next.(req, acc, fun, state)
  end
end

Req.new("https://httpbingo.org/status/404")
|> Req.Request.prepend_request_steps(expect: &MyApp.expect_successful/5)
|> Req.request!()
More complicated wrappers will maintain their state.
The contract for wrappers is:
wrapper :: (req, acc, fun, state, next ->
             {:ok, resp, acc, state}
             | {:halt, resp, acc, state}
             | {{:error, err}, resp, acc, state})
fun is:
fun :: (event, resp, acc, state ->
          {:ok, resp, acc, state}
          | {:halt, resp, acc, state}
          | {{:error, err}, resp, acc, state})
when req: Req.Request.t(),
     resp: Req.Response.t(),
     err: Exception.t(),
     acc: term(),
     state: term(),
     event:
       {:status, non_neg_integer()}
       | {:headers, [{binary(), binary()}]}
       | {:data, term()}
       | {:trailers, [{binary(), binary()}]}
next is:
next :: (req, acc, fun, state ->
           {:ok, resp, acc, state}
           | {:halt, resp, acc, state}
           | {{:error, err}, resp, acc, state})
when req: Req.Request.t(),
     resp: Req.Response.t(),
     err: Exception.t(),
     acc: term(),
     state: term()
Here's another example, a simplistic redirect feature:
defmodule MyApp do
  @redirect_statuses [301, 302, 307, 308]

  def redirect(req, acc, fun, state, next) do
    next.(req, acc, wrap(fun, next), state)
  end

  defp wrap(fun, next) do
    fn
      {:headers, _headers}, resp, acc, state
      when resp.status in @redirect_statuses ->
        [location] = Req.Response.get_header(resp, "location")
        req = resp.request
        req = update_in(req.url, &URI.merge(&1, location))

        with {:ok, resp, acc, state} <- next.(req, acc, wrap(fun, next), state) do
          {:halt, resp, acc, state}
        end

      event, resp, acc, state ->
        fun.(event, resp, acc, state)
    end
  end
end

Req.Request.new(url: "https://httpbingo.org/redirect/3")
|> Req.Request.prepend_request_steps(redirect: &MyApp.redirect/5)
|> Req.request!()
acc and fun are the ones given to Req.stream(req, acc, fun, options \\ []).
Most steps usually just pass them through unchanged. However, if you want to process response as
it comes in, you'd want to maintain your own state. Here's a simplistic streaming NDJSON decoder:
defmodule MyApp do
  def decode(%Req.Request{} = req, acc, fun, state, next) do
    fun = fn
      {:data, data}, resp, acc, [buffer | state] ->
        {lines, [buffer]} = Enum.split(String.split(buffer <> data, "\n"), -1)
        values = for line <- lines, line != "", do: JSON.decode!(line)
        {tag, resp, acc, state} = fun.({:data, values}, resp, acc, state)
        {tag, resp, acc, [buffer | state]}

      event, resp, acc, [buffer | state] ->
        {tag, resp, acc, state} = fun.(event, resp, acc, state)
        {tag, resp, acc, [buffer | state]}
    end

    {tag, resp, acc, [_buffer | state]} = next.(req, acc, fun, ["" | state])
    {tag, resp, acc, state}
  end
end

req =
  Req.Request.new()
  |> Req.Request.prepend_request_steps(decode: &MyApp.decode/5)

Req.stream(
  req,
  nil,
  fn values, _resp, acc ->
    IO.inspect(Enum.map(values, &Map.take(&1, ["id"])))
    {:cont, acc}
  end,
  url: "https://httpbingo.org/stream/3"
)
# Output: [%{"id" => 0}]
# Output: [%{"id" => 1}]
# Output: [%{"id" => 2}]
Adapters
By default Req uses Finch (via Req.Finch) and supports arbitrary adapters implementing
Req.Adapter behaviour. Req adapters are closely related to step wrappers described in previous
section.
Plugins
Custom steps can be packaged into plugins so that they are even easier to use by others.
By convention, a plugin module exports a def attach(%Req.Request{} = req) function:
Here's an example plugin:
defmodule PrintHeaders do
  @doc """
  Prints request and response headers.

  ## Request Options

    * `:print_headers` - if `true`, prints the headers. Defaults to `false`.

  """
  def attach(%Req.Request{} = req) do
    req
    |> Req.Request.register_options([:print_headers])
    |> Req.Request.append_request_steps(print_headers: __MODULE__)
  end

  def stream(%Req.Request{} = req, acc, fun, state, next) do
    if req.options[:print_headers] do
      for {name, value} <- Req.get_headers_list(req) do
        IO.puts(["> ", name, ": ", value])
      end

      with {:ok, resp, acc, state} <- next.(req, acc, fun, state) do
        for {name, value} <- Req.get_headers_list(resp) do
          IO.puts(["< ", name, ": ", value])
        end

        {:ok, resp, acc, state}
      end
    else
      next.(req, acc, fun, state)
    end
  end
end
And here is how we can use it:
req = Req.new() |> PrintHeaders.attach()

resp = Req.get!(req, url: "https://httpbingo.org/json")
resp.status
#=> 200

resp = Req.get!(req, url: "https://httpbingo.org/json", print_headers: true)
# Output: > accept-encoding: br, gzip
# Output: > user-agent: req/0.3.0-dev
# Output: < date: Wed, 12 Aug 2026 09:07:49 GMT
# Output: < content-type: application/json
# ...
resp.status
#=> 200
As you can see a plugin is simply a module. While this is not enforced, the plugin should follow
these conventions:
	It should export an attach/1 function that takes and returns the request struct

	The attach functions mostly just adds steps and it is the steps that do the actual work

	A user should be able to attach your plugin alongside other plugins. For this reason,
plugin functionality should usually only happen on a specific "trigger": on a specific
option, on a specific URL scheme or host, etc. This is especially important for plugins
that perform authentication; you don't want to accidentally expose a token from service A
when a user makes request to service B.

	If your plugin supports custom options, register them with register_options/2

	Sometimes it is useful to pass options when attaching the plugin. For that, export an
attach/2 function and call merge_options/2. Remember to first register
options before merging!

A function for streaming request body chunks.
Only supported in Req.stream/4; the function receives the accumulator passed
to Req.stream/4.

          @type t() :: %Req.Request{
  adapter: module(),
  body: iodata() | Enumerable.t() | req_body_fun(term()) | nil,
  error_steps: term(),
  halted: term(),
  headers: %{optional(binary()) => [binary()]},
  into: nil | :self | Collectable.t(),
  method: atom(),
  options: options(),
  private: map(),
  registered_options: term(),
  request_steps: [{name :: atom(), request_step()}],
  response_steps: term(),
  url: URI.t()
}


      


The request struct.

          @spec append_request_steps(t(), keyword(request_step() | module())) :: t()


      


Appends steps to the existing steps.
Examples
Req.Request.append_request_steps(
  req,
  noop: fn req -> req,
  inspect: &IO.inspect/1
)

          @spec delete_header(t(), binary()) :: t()


      


Deletes the header given by name.
All occurrences of the header are deleted, in case the header is repeated multiple times.
See also "Headers" section in Req module documentation.
Examples
iex> Req.Request.get_header(req, "cache-control")
["max-age=600", "no-transform"]
iex> req = Req.Request.delete_header(req, "cache-control")
iex> Req.Request.get_header(req, "cache-control")
[]

  



  
    
      
    
    
      delete_option(request, key)



        
          
        

    

  


  

      

          @spec delete_option(t(), atom()) :: t()


      


Deletes the given option key.
Examples
iex> req = Req.Request.new(options: [a: 1])
iex> Req.Request.get_option(req, :a)
1
iex> req = Req.Request.delete_option(req, :a)
iex> Req.Request.get_option(req, :a)
nil

          @spec drop_options(t(), [atom()]) :: t()


      


Drops the given keys from options.
Examples
iex> req = Req.Request.new(options: [a: 1, b: 2, c: 3])
iex> req = Req.Request.drop_options(req, [:a, :b])
iex> Req.Request.get_option(req, :a)
nil
iex> Req.Request.get_option(req, :c)
3

          @spec fetch_option(t(), atom()) :: {:ok, term()} | :error


      


Fetches the value for the option key.
See also get_option/3.
Examples
iex> req = Req.Request.new(options: [a: 1])
iex> Req.Request.fetch_option(req, :a)
{:ok, 1}
iex> Req.Request.fetch_option(req, :b)
:error

          @spec fetch_option!(t(), atom()) :: term()


      


Fetches the value for the option key or raises if it's not set.
See also get_option/3.
Examples
iex> req = Req.Request.new(options: [a: 1])
iex> Req.Request.fetch_option!(req, :a)
1
iex> Req.Request.fetch_option!(req, :b)
** (KeyError) option :b is not set

  



  
    
      
    
    
      get_header(req, name)



        
          
        

    

  


  

      

          @spec get_header(t(), binary()) :: [binary()]


      


Returns the values of the header specified by name.
See also "Headers" section in Req module documentation.
Examples
iex> req = Req.new(headers: [{"accept", "application/json"}])
iex> Req.Request.get_header(req, "accept")
["application/json"]
iex> Req.Request.get_header(req, "x-unknown")
[]

  



    

  
    
      
    
    
      get_option(request, key, default \\ nil)



        
          
        

    

  


  

      

          @spec get_option(t(), atom(), term()) :: term()


      


Gets the value for the option key.
See also fetch_option!/2.
Examples
iex> req = Req.Request.new(options: [a: 1])
iex> Req.Request.get_option(req, :a)
1
iex> Req.Request.get_option(req, :b)
nil
iex> Req.Request.get_option(req, :b, 0)
0

          @spec get_option_lazy(t(), atom(), (-> term())) :: term()


      


Gets the value for the option key.
This is useful if the default value is very expensive to calculate or generally
difficult to setup and teardown again.
See also get_option/3.
Examples
iex> req = Req.Request.new(options: [a: 1])
iex> fun = fn ->
...>   # some expensive operation here
...>   42
...> end
iex> Req.Request.get_option_lazy(req, :a, fun)
1
iex> Req.Request.get_option_lazy(req, :b, fun)
42

          @spec get_private(t(), atom(), default) :: term() | default when default: var


      


Gets the value for a specific private key.

          @spec merge_new_options(t(), keyword()) :: t()


      


Merges given options into the request unless they are already set.
Examples
iex> req = Req.new(auth: {:basic, "alice:secret"})
iex> req.options
%{auth: {:basic, "alice:secret"}}
iex> req = Req.Request.merge_new_options(req, auth: {:bearer, "abcd"}, base_url: "https://example.com")
iex> req.options
%{auth: {:basic, "alice:secret"}, base_url: "https://example.com"}

iex> req = Req.new()
iex> Req.Request.merge_new_options(req, foo: :bar)
** (ArgumentError) unknown option :foo

          @spec merge_options(t(), keyword()) :: t()


      


Merges given options into the request.
Examples
iex> req = Req.new(auth: {:basic, "alice:secret"}, retry: false)
iex> req = Req.Request.merge_options(req, auth: {:bearer, "abcd"}, base_url: "https://example.com")
iex> req.options[:auth]
{:bearer, "abcd"}
iex> req.options[:retry]
false
iex> req.options[:base_url]
"https://example.com"

  



    

  
    
      
    
    
      new(options \\ [])



        
          
        

    

  


  

      

          @spec new(keyword()) :: t()


      


Returns a new request struct.
Options
	:method - the request method, defaults to :get.

	:url - the request URL.

	:headers - the request headers, defaults to [].

	:body - the request body, defaults to nil.

	:adapter - the request adapter, defaults to Req.Finch.


Examples
iex> req = Req.Request.new(url: "https://api.github.com/repos/wojtekmach/req")
iex> resp = Req.request!(req)
iex> resp.request.url.host
"api.github.com"
iex> resp.status
200

  



  
    
      
    
    
      prepend_request_steps(request, steps)



        
          
        

    

  


  

      

          @spec prepend_request_steps(t(), keyword(request_step() | module())) :: t()


      


Prepends steps to the existing steps.
Examples
Req.Request.prepend_request_steps(
  req,
  noop: fn req -> req end,
  inspect: &IO.inspect/1
)

          @spec put_header(t(), binary(), binary()) :: t()


      


Sets the header name to value.
The value can be a binary or a list of binaries,
If the header was previously set, its value is overwritten.
See also "Headers" section in Req module documentation.
Examples
iex> req = Req.new()
iex> Req.Request.get_header(req, "accept")
[]
iex> req = Req.Request.put_header(req, "accept", "application/json")
iex> Req.Request.get_header(req, "accept")
["application/json"]

  



  
    
      
    
    
      put_headers(request, headers)



        
          
        

    

  


  

      

          @spec put_headers(t(), [{binary(), binary()}]) :: t()


      


Adds (or replaces) multiple request headers.
See put_header/3 for more information.
Examples
iex> req = Req.new()
iex> req = Req.Request.put_headers(req, [{"accept", "text/html"}, {"accept-encoding", "gzip"}])
iex> Req.Request.get_header(req, "accept")
["text/html"]
iex> Req.Request.get_header(req, "accept-encoding")
["gzip"]

  



  
    
      
    
    
      put_new_header(request, name, value)



        
          
        

    

  


  

      

          @spec put_new_header(t(), binary(), binary()) :: t()


      


Adds a request header name unless already present.
See put_header/3 for more information.
Examples
iex> req =
...>   Req.new()
...>   |> Req.Request.put_new_header("accept", "application/json")
...>   |> Req.Request.put_new_header("accept", "application/html")
iex> Req.Request.get_header(req, "accept")
["application/json"]

  



  
    
      
    
    
      put_new_option(request, key, value)



        
          
        

    

  


  

      

          @spec put_new_option(t(), atom(), term()) :: t()


      


Sets the value value for the option name unless option is already set.
See also put_option/3, merge_options/2, and merge_new_options/2.
Examples
iex> req = Req.Request.new() |> Req.Request.register_options([:a])
iex> req.options
%{}
iex> req = Req.Request.put_new_option(req, :a, 1)
iex> req.options
%{a: 1}
iex> req = Req.Request.put_new_option(req, :a, 2)
iex> req.options
%{a: 1}

iex> req = Req.Request.new()
iex> Req.Request.put_new_option(req, :b, 2)
** (ArgumentError) unknown option :b

  



  
    
      
    
    
      put_option(request, key, value)



        
          
        

    

  


  

      

          @spec put_option(t(), atom(), term()) :: t()


      


Sets the value value for the option name.
See also put_new_option/3, merge_options/2, and merge_new_options/2.
Examples
iex> req = Req.Request.new() |> Req.Request.register_options([:a])
iex> req.options
%{}
iex> req = Req.Request.put_option(req, :a, 1)
iex> req.options
%{a: 1}

iex> req = Req.Request.new()
iex> Req.Request.put_option(req, :b, 2)
** (ArgumentError) unknown option :b

  



  
    
      
    
    
      put_private(request, key, value)



        
          
        

    

  


  

      

          @spec put_private(t(), atom(), term()) :: t()


      


Assigns a private key to value.

          @spec register_options(t(), [atom()]) :: t()


      


Registers options to be used by custom steps.
Req ensures that all used options were previously registered which helps
finding accidentally mistyped option names. If you're adding custom steps
that are accepting options, call this function to register them.
Examples
iex> Req.request!(urll: "https://httpbingo.org")
** (ArgumentError) unknown option :urll. Did you mean :url?

iex> Req.new(bas_url: "https://httpbingo.org")
** (ArgumentError) unknown option :bas_url. Did you mean :base_url?

req =
  Req.new(base_url: "https://httpbingo.org")
  |> Req.Request.register_options([:foo])

Req.get!(req, url: "/status/201", foo: :bar).status
#=> 201

          @spec update_private(t(), key :: atom(), default :: term(), (term() -> term())) :: t()


      


Updates private key with the given function.
If key is present in request private map then the existing value is passed to fun and its
result is used as the updated value of key. If key is not present, default is inserted
as the value of key. The default value will not be passed through the update function.
Examples
iex> req = %Req.Request{private: %{a: 1}}
iex> Req.Request.update_private(req, :a, 11, & &1 + 1).private
%{a: 2}
iex> Req.Request.update_private(req, :b, 11, & &1 + 1).private
%{a: 1, b: 11}

The response struct.
Fields:
	:status - the HTTP status code.

	:headers - the HTTP response headers. The header names should be downcased.
See also "Headers" section in Req module documentation.

	:body - the HTTP response body.

	:trailers - the HTTP response trailers. The trailer names must be downcased.

	:private - a map reserved for libraries and frameworks to use.
Prefix the keys with the name of your project to avoid any future
conflicts. Only accepts atom/0 keys.

	:request - the request that produced this response.

        delete_header(resp, name)

      


        Deletes the header given by name.



    


    
      
        get_header(resp, name)

      


        Returns the values of the header specified by name.



    


    
      
        get_private(response, key, default \\ nil)

      


        Gets the value for a specific private key.



    


    
      
        get_retry_after(response)

      


        Returns the retry-after header delay value in seconds.



    


    
      
        json(response \\ new(), body)

      


        Builds or updates a response with JSON body.



    


    
      
        new(options \\ [])

      


        Returns a new response.



    


    
      
        put_header(resp, name, value)

      


        Adds a new response header name if not present, otherwise replaces the
previous value of that header with value.



    


    
      
        put_private(response, key, value)

      


        Assigns a private key to value.



    


    
      
        to_map(resp)

      


        Converts response to a map for interoperability with other libraries.



    


    
      
        update_private(response, key, initial, fun)

      


        Updates private key with the given function.

          @type t() :: %Req.Response{
  body:
    binary()
    | %Req.Response.Async{
        cancel_fun: term(),
        pid: term(),
        ref: term(),
        stream_fun: term()
      }
    | term(),
  headers: %{optional(binary()) => [binary()]},
  private: map(),
  request: Req.Request.t() | nil,
  status: non_neg_integer(),
  trailers: %{optional(binary()) => [binary()]}
}

      delete_header(resp, name)



        
          
        

    

  


  

Deletes the header given by name.
All occurrences of the header are deleted, in case the header is repeated multiple times.
See also "Headers" section in Req module documentation.
Examples
iex> Req.Response.get_header(resp, "cache-control")
["max-age=600", "no-transform"]
iex> resp = Req.Response.delete_header(resp, "cache-control")
iex> Req.Response.get_header(resp, "cache-control")
[]

  



  
    
      
    
    
      get_header(resp, name)



        
          
        

    

  


  

      

          @spec get_header(t(), binary()) :: [binary()]


      


Returns the values of the header specified by name.
See also "Headers" section in Req module documentation.
Examples
iex> Req.Response.get_header(response, "content-type")
["application/json"]

  



    

  
    
      
    
    
      get_private(response, key, default \\ nil)



        
          
        

    

  


  

      

          @spec get_private(t(), key :: atom(), default :: term()) :: term()


      


Gets the value for a specific private key.

  



  
    
      
    
    
      get_retry_after(response)



        
          
        

    

  


  

      

          @spec get_retry_after(t()) :: integer() | nil


      


Returns the retry-after header delay value in seconds.
Returns nil if the header is not found or the computed number of seconds is negative.

          @spec json(t(), body :: term()) :: t()


      


Builds or updates a response with JSON body.
Example
iex> Req.Response.json(%{hello: 42})
%Req.Response{
  status: 200,
  headers: %{"content-type" => ["application/json"]},
  body: ~s|{"hello":42}|
}

iex> resp = Req.Response.new()
iex> Req.Response.json(resp, %{hello: 42})
%Req.Response{
  status: 200,
  headers: %{"content-type" => ["application/json"]},
  body: ~s|{"hello":42}|
}
If the response already contains a 'content-type' header, it is kept as is:
iex> Req.Response.new()
iex> |> Req.Response.put_header("content-type", "application/vnd.api+json; charset=utf-8")
iex> |> Req.Response.json(%{hello: 42})
%Req.Response{
  status: 200,
  headers: %{"content-type" => ["application/vnd.api+json; charset=utf-8"]},
  body: ~s|{"hello":42}|
}

  



    

  
    
      
    
    
      new(options \\ [])



        
          
        

    

  


  

      

          @spec new(options :: keyword() | map() | struct()) :: t()


      


Returns a new response.
Expects a keyword list, map, or struct containing the response keys.
Example
iex> Req.Response.new(status: 200, body: "body")
%Req.Response{status: 200, headers: %{}, body: "body"}

iex> finch_response = %Finch.Response{status: 200, headers: [{"content-type", "text/html"}]}
iex> Req.Response.new(finch_response)
%Req.Response{status: 200, headers: %{"content-type" => ["text/html"]}, body: ""}

  



  
    
      
    
    
      put_header(resp, name, value)



        
          
        

    

  


  

      

          @spec put_header(t(), binary(), binary()) :: t()


      


Adds a new response header name if not present, otherwise replaces the
previous value of that header with value.
See also "Headers" section in Req module documentation.
Examples
iex> resp = Req.Response.put_header(%Req.Response{}, "content-type", "application/json")
iex> resp.headers
%{"content-type" => ["application/json"]}

  



  
    
      
    
    
      put_private(response, key, value)



        
          
        

    

  


  

      

          @spec put_private(t(), key :: atom(), value :: term()) :: t()


      


Assigns a private key to value.

          @spec to_map(t()) :: %{
  status: non_neg_integer(),
  headers: [{binary(), binary()}],
  trailers: [{binary(), binary()}],
  body: term()
}


      


Converts response to a map for interoperability with other libraries.
The resulting map has the following fields:
	:status
	:headers
	:trailers
	:body

Note, body can be any term since Req built-in and custom steps usually transform it.
Examples
iex> resp = Req.Response.new(status: 200, headers: %{"server" => ["test"]}, body: "hello")
iex> Req.Response.to_map(resp)
%{status: 200, body: "hello", headers: [{"server", "test"}], trailers: []}

  



  
    
      
    
    
      update_private(response, key, initial, fun)



        
          
        

    

  


  

      

          @spec update_private(t(), key :: atom(), default :: term(), (term() -> term())) :: t()


      


Updates private key with the given function.
If key is present in the response private map then the existing value is passed to fun and its
result is used as the updated value of key. If key is not present, default is inserted
as the value of key. The default value will not be passed through the update function.
Examples
iex> resp = %Req.Response{private: %{a: 1}}
iex> Req.Response.update_private(resp, :a, 11, & &1 + 1).private
%{a: 2}
iex> Req.Response.update_private(resp, :b, 11, & &1 + 1).private
%{a: 1, b: 11}

Asynchronous response body.
This is the response.body when making a request with into: :self, that is,
streaming response body chunks to the current process mailbox.
This struct implements the Enumerable protocol where each element is a body chunk received
from the current process mailbox. HTTP Trailer fields are ignored.
If the request is sent using HTTP/1, an extra process is spawned to consume messages from the
underlying socket. On both HTTP/1 and HTTP/2 the messages are sent to the current process as
soon as they arrive, as a firehose. If you wish to maximize request rate or have more control
over how messages are streamed, use Req.stream/4 or into: collectable instead.
Note: This feature is currently experimental and it may change in future releases.
Examples
iex> resp = Req.get!("https://httpbingo.org/stream/3", into: :self)
iex> resp.body
#Req.Response.Async<...>
iex> Enum.each(resp.body, &IO.puts/1)
# {"id":0}
# {"id":1}
# {"id":2}
:ok

Req testing conveniences.
Req is composed of:
	Req - the high-level API

	Req.Request - the low-level API and the request struct

	Req.Auth, …, Req.Steps - a collection of built-in steps.

	Req.Test - the testing conveniences (you're here!)


Req.Test allows you to:
	Create request stubs using Req.Test.stub(name, plug) and mocks
using Req.Test.expect(name, count, plug). Both can be used in concurrent
tests.

	Configure Req to run requests through mocks/stubs by setting plug: {Req.Test, name}.
This works because Req.Test itself is a plug whose job is to fetch the mocks/stubs under
name.

	Easily create JSON responses with Req.Test.json(conn, body),
HTML responses with Req.Test.html(conn, body), and
text responses with Req.Test.text(conn, body).

	Simulate network errors with Req.Test.transport_error(conn, reason).


Mocks and stubs are using the same ownership model of
nimble_ownership, also used by
Mox. This allows Req.Test to be used in concurrent tests.
Example
Imagine we're building an app that displays weather for a given location using an HTTP weather
service:
defmodule MyApp.Weather do
  def get_rating(location) do
    case get_temperature(location) do
      {:ok, %{status: 200, body: %{"celsius" => celsius}}} ->
        cond do
          celsius < 18.0 -> {:ok, :too_cold}
          celsius < 30.0 -> {:ok, :nice}
          true -> {:ok, :too_hot}
        end

      _ ->
        :error
    end
  end

  def get_temperature(location) do
    [
      base_url: "https://weather-service",
      params: [location: location]
    ]
    |> Keyword.merge(Application.get_env(:myapp, :weather_req_options, []))
    |> Req.request()
  end
end
We configure it for production:
# config/runtime.exs
config :myapp, weather_req_options: [
  auth: {:bearer, System.fetch_env!("MYAPP_WEATHER_API_KEY")}
]
In tests, instead of hitting the network, we make the request against
a plug stub named MyApp.Weather:
# config/test.exs
config :myapp, weather_req_options: [
  plug: {Req.Test, MyApp.Weather}
]
Now we can control our stubs in concurrent tests:
use ExUnit.Case, async: true

test "nice weather" do
  Req.Test.stub(MyApp.Weather, fn conn ->
    Req.Test.json(conn, %{"celsius" => 25.0})
  end)

  assert MyApp.Weather.get_rating("Krakow, Poland") == {:ok, :nice}
end
Concurrency and Allowances
The example above works in concurrent tests because MyApp.Weather.get_rating/1 calls
directly to Req.request/1 in the same process. It also works in many cases where the
request happens in a spawned process, such as a Task, GenServer, and more.
However, if you are encountering issues with stubs not being available in spawned processes,
it's likely that you'll need explicit allowances. For example, if
MyApp.Weather.get_rating/1 was calling Req.request/1 in a process spawned with spawn/1,
the stub would not be available in the spawned process:
# With code like this, the stub would not be available in the spawned task:
def get_rating_async(location) do
  spawn(fn -> get_rating(location) end)
end
To make stubs defined in the test process available in other processes, you can use
allow/3. For example, imagine that the call to MyApp.Weather.get_rating/1
was happening in a spawned GenServer:
test "nice weather" do
  {:ok, pid} = start_gen_server(...)

  Req.Test.stub(MyApp.Weather, fn conn ->
    Req.Test.json(conn, %{"celsius" => 25.0})
  end)

  Req.Test.allow(MyApp.Weather, self(), pid)

  assert get_weather(pid, "Krakow, Poland") == {:ok, :nice}
end
Broadway
If you're using Req.Test with Broadway, you may need to use
allow/3 to make stubs available in the Broadway processors. A great way to do that is
to hook into the Telemetry events that Broadway publishes to
manually allow the processors and batch processors to access the stubs. This approach is
similar to what is documented in Broadway
itself.
First, you should add the test PID (which is allowed to use the Req stub) to the metadata
for the test events you're publishing:
Broadway.test_message(MyApp.Pipeline, message, metadata: %{req_stub_owner: self()})
Then, you'll need to define a test helper to hook into the Telemetry events. For example,
in your test/test_helper.exs file:
defmodule BroadwayReqStubs do
  def attach(stub) do
    events = [
      [:broadway, :processor, :start],
      [:broadway, :batch_processor, :start],
    ]

    :telemetry.attach_many({__MODULE__, stub}, events, &__MODULE__.handle_event/4, %{stub: stub})
  end

  def handle_event(_event_name, _event_measurement, %{messages: messages}, %{stub: stub}) do
    with [%Broadway.Message{metadata: %{req_stub_owner: pid}} | _] <- messages do
      :ok = Req.Test.allow(stub, pid, self())
    end

    :ok
  end
end
Last but not least, attach the helper in your test/test_helper.exs:
BroadwayReqStubs.attach(MyStub)

    Functions
  


    
      
        html(conn, data)

      


        Sends HTML response.



    


    
      
        json(conn, data)

      


        Sends JSON response.



    


    
      
        raw_body(conn)

      


        Reads the raw request body from a plug request.



    


    
      
        redirect(conn, opts)

      


        Sends redirect response to the given url.



    


    
      
        text(conn, data)

      


        Sends text response.



    


    
      
        transport_error(conn, reason)

      


        Simulates a network transport error.

Req.Auth 
    



      
Sets request authentication.
For HTTP Digest authentication, when the response is HTTP 401 with a www-authenticate
header, this step calculates the authorization: Digest ... header and makes another
request.
Request Options
	:auth - sets the authorization header:
	string - sets to this value;

	{:basic, userinfo} - uses Basic HTTP authentication;

	{:digest, userinfo} - uses Digest HTTP authentication;

	{:bearer, token} - uses Bearer HTTP authentication;

	:netrc - load credentials from .netrc at path specified in NETRC environment variable.
If NETRC is not set, load .netrc in user's home directory;

	{:netrc, path} - load credentials from path

	fn -> {:bearer, "eyJ0eXAi..." } end - a 0-arity function that returns one of the aforementioned types.

	{mod, fun, args} - an MFArgs tuple that returns one of the aforementioned types.




Examples
iex> Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: {:basic, "foo:foo"}).status
401
iex> Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: {:basic, "foo:bar"}).status
200
iex> Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: fn -> {:basic, "foo:bar"} end).status
200
iex> Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: {Authentication, :fetch_token, []}).status
200

iex> Req.get!("https://httpbingo.org/digest-auth/auth/user/pass", auth: {:digest, "user:pass"}).status
200

iex> Req.get!("https://httpbingo.org/bearer", auth: {:bearer, ""}).status
401
iex> Req.get!("https://httpbingo.org/bearer", auth: {:bearer, "foo"}).status
200
iex> Req.get!("https://httpbingo.org/bearer", auth: fn -> {:bearer, "foo"} end).status
200

iex> System.put_env("NETRC", "./test/my_netrc")
iex> Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: :netrc).status
200

iex> Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: {:netrc, "./test/my_netrc"}).status
200
iex> Req.get!("https://httpbingo.org/basic-auth/foo/bar", auth: fn -> {:netrc, "./test/my_netrc"} end).status
200

Verifies the response body against the expected checksum.
Request Options
	:checksum - if set, this is the expected response body checksum.
Can be one of:
	"md5:(...)"
	"sha1:(...)"
	"sha256:(...)"



Examples
iex> resp = Req.get!("https://httpbingo.org/json", checksum: "sha1:ae5891fe71e8c6432b552b0c3b4394e43f151493")
iex> resp.status
200

iex> Req.get!("https://httpbingo.org/json", checksum: "sha1:bad")
** (Req.ChecksumMismatchError) checksum mismatch
expected: sha1:bad
actual:   sha1:ae5891fe71e8c6432b552b0c3b4394e43f151493

Decodes response body based on the detected format.
To decode other formats, or to add support for custom ones, use the :decoders option.
Built-in decoders
	Format	Decoder	Enabled	Streaming Decoding
	:json, :json_api	Req.JSON	✓	
	:ndjson	Req.NDJSON	✓	✓
	:sse	Req.SSE	✓	✓
	:zip	Req.ZIP		
	:tar, :tgz	Req.Tar		
	:gz	Req.Gzip		✓
	:zst	Req.Zstd (requires Erlang/OTP 28+)		✓
	:csv	Req.CSV (requires nimble_csv)		

The format is determined by the response content-type header. See MIME for registering
content-type/format mapping.
Decompression Bombs
The archive and compression decoders (:zip, :tar, :tgz, :gz, and :zst) decompress
the whole response body into memory with no size limit, so a small response can expand to
many gigabytes. For this reason they are not enabled by default; only opt into them via
the :decoders option for endpoints you trust.
Request Options
	:decoders - the list of decoders to use. Defaults to
[:json, :json_api, :ndjson, :sse].
Each element is either:
	a format (atom) handled by a built-in decoder,
e.g. :json or :zip;

	a {format, decoder} or {content_type, decoder} tuple, where format is an atom e.g.:
:json, content_type is a binary e.g.: application/x-amz-json-1.0, and decoder is
one of:
	another format (atom), to reuse a built-in decoder, e.g. decoders: [json5: :json].

	a 1-arity function that returns {:ok, term} or {:error, exception}, e.g.:
decoders: [{"text/calendar", &{:ok, ICal.from_ics(&1)}}]




Setting :decoders replaces the default, so include :json if you still want JSON decoded:
# handles json, zip, and tar:
Req.new(decoders: [:json, :zip, :tar])
Set :decoders to false to disable all decoding, including JSON.

	:decode_body - if set to false, disables automatic response body decoding.
Defaults to true.

	:raw - if set to true, disables response body decoding. Defaults to false.
Note: setting raw: true also disables response body decompression.


Examples
Decode JSON:
iex> response = Req.get!("https://httpbingo.org/json")
...> response.body["slideshow"]["title"]
"Sample Slide Show"
Decode a ZIP archive (opt-in):
iex> response = Req.get!("https://example.com/archive.zip", decoders: [:zip])
...> response.body["file.txt"]
"contents"

Req.Decompress 
    



      
Asks the server to return compressed response.
The response body is decompressed based on the content-encoding response header. This step
is off by default; set compressed: true to opt in.
Supported formats:
	Format	Decoder
	gzip, x-gzip	:zlib
	br	:brotli (if :brotli is installed)
	zstd	:zstd (requires Erlang/OTP 28+)
	other	Returns data as is

This step updates the following headers to reflect the changes:
	content-encoding is removed
	content-length is removed

Only enable compression for trusted servers
This step decompresses the whole response body into memory with no size limit, so a small
response can expand into many gigabytes. A malicious or compromised server can exploit this
to exhaust memory and crash the client (a decompression bomb / denial of service). For this
reason compression is off by default; only set compressed: true for endpoints you trust.
Request Options
	:compressed - if set to true, sets the accept-encoding header with compression
algorithms that Req supports and decompresses the response body. Defaults to false.

	:raw - if set to true, disables response body decompression. Defaults to false.
Note: setting raw: true also disables response body decoding.


Examples
By default, Req does not ask for a compressed response. Pass compressed: true to request one
and have Req decompress the body, so we get back the decompressed content:
iex> response = Req.get!("https://elixir-lang.org", compressed: true)
iex> response.body |> binary_part(0, 15)
"<!DOCTYPE html>"
To inspect the raw compressed bytes the server sent, additionally pass raw: true, which
disables decompression. Notice the body now starts with <<31, 139>>, the "magic bytes"
for gzip:
iex> response = Req.get!("https://elixir-lang.org", compressed: true, raw: true)
iex> Req.Response.get_header(response, "content-encoding")
["gzip"]
iex> response.body |> binary_part(0, 2)
<<31, 139>>
Zstandard is supported out of the box on Erlang/OTP 28+ (via the built-in :zstd module).
Brotli is supported if the optional :brotli package is installed:
Mix.install([
  :req,
  {:brotli, "~> 0.3.0"}
])

response = Req.get!("https://httpbingo.org/anything", compressed: true)
response.body["headers"]["Accept-Encoding"]
#=> ["zstd, br, gzip"]

Expect that response matches the given status.
This step ensures the HTTP response has the given expected status, otherwise it
returns Req.UnexpectedStatusError.
Request Options
	:expect - the expected HTTP response status. Can be one of the following:
	integer
	range
	atom - one of :informational (1xx), :successful (2xx), :redirection (3xx),
:client_error (4xx), or :server_error (5xx)
	list of integers/ranges/atoms



Order Matters!
By default, Req.Expect runs AFTER Req.Retry, Req.Redirect, Req.Decompress,
and Req.Decode steps.
This means that, for example, HTTP 503 error would be first retried,
HTTP 307 redirect would be first followed, and the response body
would be first decompressed and decoded before checking for expected HTTP status.
If this is undesirable, re-arrange or disable and manually run given steps.
Examples
iex> resp = Req.get!("https://httpbingo.org/status/200", expect: 200)
iex> resp.status
200

iex> Req.get!("https://httpbingo.org/status/404", expect: :successful)
** (Req.UnexpectedStatusError) expected response status :successful (200..299), got: 404

Follows redirects.
The original request method may be changed to GET depending on the status code:
	Code	Method handling
	301, 302, 303	Changed to GET
	307, 308	Method not changed

Request Options
	:redirect - if set to false, disables automatic response redirects.
Defaults to true.

	:redirect_trusted - by default, authorization credentials are only sent
on redirects with the same host, scheme and port. If :redirect_trusted is set
to true, credentials will be sent to any host. Defaults to false.

	:redirect_log_level - the log level to emit redirect logs at. Can also be set
to false to disable logging these messages. Defaults to :debug.

	:max_redirects - the maximum number of redirects, defaults to 10. If the
limit is reached, a Req.TooManyRedirectsError exception is returned.


Examples
iex> Req.get!("http://api.github.com").status
# 23:24:11.670 [debug] redirecting to https://api.github.com/
200

iex> Req.get!("https://httpbingo.org/redirect/4", max_redirects: 3)
# 23:07:59.570 [debug] redirecting to /relative-redirect/3
# 23:08:00.068 [debug] redirecting to /relative-redirect/2
# 23:08:00.206 [debug] redirecting to /relative-redirect/1
** (Req.TooManyRedirectsError) too many redirects (3)

iex> Req.get!("http://api.github.com", redirect_log_level: false)
200

iex> Req.get!("http://api.github.com", redirect_log_level: :error)
# 23:24:11.670 [error]  redirecting to https://api.github.com/
200

Retries a request on errors.
Request Options
	:retry - can be one of the following:
	:safe_transient (default) - retry safe (GET/HEAD) requests on one of:
	HTTP 408/429/500/502/503/504 responses

	Req.TransportError with reason: :timeout | :econnrefused | :closed

	Req.HTTPError with protocol: :http2, reason: :unprocessed | :pool_not_available



	:transient - same as :safe_transient except retries all HTTP methods (POST, DELETE, etc.)

	fun - a 2-arity function that accepts a Req.Request and either a Req.Response or an exception struct
and returns one of the following:
	true - retry using the default delay described under :retry_delay below.

	{:delay, milliseconds} - retry with the given delay.

	false/nil - don't retry.



	false - don't retry.



	:retry_delay - if not set, which is the default, the retry delay is determined by
the value of the Retry-After header on HTTP 429/503 responses. If the header is not set,
or the header value is negative, the default delay follows a simple exponential backoff
with jitter, for example: 0.949s, 1.97s, 3.87s, 7.55s, ...
:retry_delay can be set to a function that receives the retry count (starting at 0)
and returns the delay, the number of milliseconds to sleep before making another attempt.

	:retry_log_level - the log level to emit retry logs at. Can also be set to false to disable
logging these messages. Defaults to :warning.

	:max_retries - maximum number of retry attempts, defaults to 3 (for a total of 4
requests to the server, including the initial one.)


Examples
iex> Req.get!("https://httpbingo.org/status/500,200").status
# 08:43:19.101 [warning] retry: got response with status 500, will retry in 941ms, 2 attempts left
# 08:43:22.958 [warning] retry: got response with status 500, will retry in 1877ms, 1 attempt left
200

A collection of built-in steps.
Req is composed of:
	Req - the high-level API

	Req.Request - the low-level API and the request struct

	Req.Auth, …, Req.Steps - a collection of built-in steps (you're here!)

	Req.Test - the testing conveniences


See also step modules:
	Req.Auth

	Req.Checksum

	Req.Decode

	Req.Decompress

	Req.Expect

	Req.Redirect

	Req.Retry



      


      
        Summary


  
    Request Steps
  


    
      
        compress_body(request)

      


        Compresses the request body.



    


    
      
        encode_body(request)

      


        Encodes the request body.



    


    
      
        put_aws_sigv4(request)

      


        Signs request with AWS Signature Version 4.



    


    
      
        put_base_url(request)

      


        Sets base URL for all requests.



    


    
      
        put_params(request)

      


        Adds params to request query string.



    


    
      
        put_path_params(request)

      


        Uses a templated request path.



    


    
      
        put_range(request)

      


        Sets the "Range" request header.



    


    
      
        put_user_agent(request)

      


        Sets the user-agent header.

      compress_body(request)



        
          
        

    

  


  

Compresses the request body.
Not supported with body: req_body_fun.
Request Options
	:compress_body - if set to true, compresses the request body using gzip.
Defaults to false.

Encodes the request body.
Request Options
	:form - if set, encodes the request body as application/x-www-form-urlencoded
(using URI.encode_query/1).

	:form_multipart - if set, encodes the request body as multipart/form-data.
It accepts name / value pairs. value can be one of:
	integer (automatically encoded as string)

	iodata

	File.Stream

	Enumerable

	{value, options} tuple.
 value can be any of the values mentioned above.
 Supported options are: :filename, :content_type, and :size.
 When value is an Enumerable, option :size can be set with
 the binary size of the value. The size will be used to calculate
 and send the content-length header which might be required for
 some servers. There is no need to pass :size for integer,
 iodata, and File.Stream values as it's automatically calculated.



	:json - if set, encodes the request body as JSON (using JSON.encode_to_iodata!/1), sets
the accept header to application/json, and the content-type header to application/json.


When the request has the default HTTP method, GET, and the request body is set, this step
automatically changes HTTP method to POST.
Examples
Encoding form (application/x-www-form-urlencoded):
iex> Req.post!("https://httpbingo.org/anything", form: [a: 1]).body["form"]
%{"a" => ["1"]}
Encoding form (multipart/form-data):
iex> fields = [a: 1, b: {"2", filename: "b.txt"}]
iex> resp = Req.post!("https://httpbingo.org/anything", form_multipart: fields)
iex> resp.body["form"]
%{"a" => ["1"]}
iex> resp.body["files"]
%{"b" => ["2"]}
Encoding streaming form (multipart/form-data):
iex> stream = Stream.cycle(["abc"]) |> Stream.take(3)
iex> fields = [file: {stream, filename: "b.txt"}]
iex> resp = Req.post!("https://httpbingo.org/anything", form_multipart: fields)
iex> resp.body["files"]
%{"file" => ["abcabcabc"]}

# with explicit :size
iex> stream = Stream.cycle(["abc"]) |> Stream.take(3)
iex> fields = [file: {stream, filename: "b.txt", size: 9}]
iex> resp = Req.post!("https://httpbingo.org/anything", form_multipart: fields)
iex> resp.body["files"]
%{"file" => ["abcabcabc"]}
Encoding JSON:
iex> Req.post!("https://httpbingo.org/post", json: %{a: 1}).body["json"]
%{"a" => 1}
Automatically change GET to POST when body is set:
iex> Req.request!("https://httpbingo.org/post", json: %{a: 1}).body["json"]
%{"a" => 1}

Signs request with AWS Signature Version 4.
Request Options
	:aws_sigv4 - if set, the AWS options to sign request:
	:access_key_id - the AWS access key id.

	:secret_access_key - the AWS secret access key.

	:token - if set, the AWS security token, for example returned from AWS STS.

	:service - the AWS service. We try to automatically detect the service (e.g.
s3.amazonaws.com host sets service to :s3)

	:region - the AWS region. Defaults to "us-east-1".

	:datetime - the request datetime, defaults to DateTime.utc_now(:second).


Additionally, it can be an {mod, fun, args} tuple that returns the above
options.


Examples
iex> req =
...>   Req.new(
...>     base_url: "https://s3.amazonaws.com",
...>     aws_sigv4: [
...>       access_key_id: System.get_env("AWS_ACCESS_KEY_ID"),
...>       secret_access_key: System.get_env("AWS_SECRET_ACCESS_KEY")
...>     ]
...>   )
iex>
iex> %{status: 200} = Req.put!(req, url: "/bucket1/key1", body: "Hello, World!")
iex> resp = Req.get!(req, url: "/bucket1/key1").body
"Hello, World!"
Request body streaming also works though content-length header must be explicitly set:
iex> path = "a.txt"
iex> File.write!(path, String.duplicate("a", 100_000))
iex> size = File.stat!(path).size
iex> chunk_size = 10 * 1024
iex> stream = File.stream!(path, chunk_size)
iex> %{status: 200} = Req.put!(req, url: "/bucket1/key1", headers: [content_length: size], body: stream)
iex> byte_size(Req.get!(req, url: "/bucket1/key1").body)
100_000

Sets base URL for all requests.
Request Options
	:base_url - if set, the request URL is merged with this base URL.
The base url can be a string, a %URI{} struct, a 0-arity function,
or a {mod, fun, args} tuple describing a function to call.


Examples
iex> req = Req.new(base_url: "https://httpbingo.org")
iex> Req.get!(req, url: "/status/200").status
200
iex> Req.get!(req, url: "/status/201").status
201

Adds params to request query string.
Request Options
	:params - params to add to the request query string. Defaults to [].

Examples
iex> Req.get!("https://httpbingo.org/anything/query", params: [x: 1, y: 2]).body["args"]
%{"x" => ["1"], "y" => ["2"]}

  



  
    
      
    
    
      put_path_params(request)



        
          
        

    

  


  

Uses a templated request path.
By default, params in the URL path are expressed as strings prefixed with :. For example,
:code in https://httpbingo.org/status/:code. If you want to use the {code} syntax,
set path_params_style: :curly. Param names must start with a letter and can contain letters,
digits, and underscores; this is true both for :colon_params as well as {curly_params}.
Path params are replaced in the request URL path. The path params are specified as a keyword
list of parameter names and values, as in the examples below. The values of the parameters are
converted to strings using the String.Chars protocol (to_string/1).
Request Options
	:path_params - if set, params to add to the templated path. Defaults to nil.

	:path_params_style (available since v0.5.1) - how path params are expressed. Can be one of:
	:colon - (default) for Plug-style parameters, such as :code in
https://httpbingo.org/status/:code.

	:curly - for OpenAPI-style parameters, such as
{code} in https://httpbingo.org/status/{code}.




Examples
iex> Req.get!("https://httpbingo.org/status/:code", path_params: [code: 201]).status
201

iex> Req.get!("https://httpbingo.org/status/{code}", path_params: [code: 201], path_params_style: :curly).status
201

  



  
    
      
    
    
      put_range(request)



        
          
        

    

  


  

Sets the "Range" request header.
Request Options
	:range - can be one of the following:
	a string - returned as is

	a first..last range - converted to "bytes=<first>-<last>"




Examples
iex> response = Req.get!("https://httpbingo.org/range/100", range: 0..3)
iex> response.status
206
iex> response.body
"abcd"
iex> Req.Response.get_header(response, "content-range")
["bytes 0-3/100"]

  



  
    
      
    
    
      put_user_agent(request)



        
          
        

    

  


  

Sets the user-agent header.
Request Options
	:user_agent - sets the user-agent header. Defaults to "req/0.8.0-rc.0".

Examples
iex> Req.get!("https://httpbingo.org/user-agent").body
%{"user-agent" => "req/0.8.0-rc.0"}

iex> Req.get!("https://httpbingo.org/user-agent", user_agent: "foo").body
%{"user-agent" => "foo"}

Req.Adapter behaviour
    



      
The adapter contract.
By default Req uses Finch (via Req.Finch) and supports arbitrary adapters implementing this
behaviour.
Req adapters are closely related to step wrappers, see
"Steps & Step Wrappers" section in Req.Request module documentation for
more information.

      


      
        Summary


  
    Callbacks
  


    
      
        stream(req, acc, fun, state)

      


    





      


      
        Callbacks


        


  
    
      
    
    
      stream(req, acc, fun, state)



        
          
        

    

  


  

      

          @callback stream(req, acc, fun, state) ::
  {:ok, resp, acc, state}
  | {:halt, resp, acc, state}
  | {{:error, err}, resp, acc, state}
when req: Req.Request.t(),
     resp: Req.Response.t(),
     err: Exception.t(),
     acc: term(),
     fun: (event, resp, acc, state ->
             {:ok, resp, acc, state}
             | {:halt, resp, acc, state}
             | {{:error, err}, resp, acc, state}),
     state: term(),
     event:
       {:status, non_neg_integer()}
       | {:headers, [{binary(), binary()}]}
       | {:data, binary()}
       | {:trailers, [{binary(), binary()}]}

Req.Finch 
    



      
Runs the request using Finch.
This is the default Req adapter. See
"Adapter" section in the Req.Request module documentation
for more information on adapters.
Finch returns Mint.TransportError exceptions on HTTP connection problems. These are automatically
converted to Req.TransportError exceptions. Similarly, HTTP-protocol-related errors,
Mint.HTTPError and Finch.Error, and converted to Req.HTTPError.
HTTP/1 Pools
On HTTP/1 connections, Finch creates a pool per {scheme, host, port} tuple. These pools
are kept around to re-use connections as much as possible, however they are not automatically
terminated. To do so, you can configure custom Finch pool:
{:ok, _} =
  Finch.start_link(
    name: MyFinch,
    pools: %{
      default: [
        # terminate idle {scheme, host, port} pool after 60s
        pool_max_idle_time: 60_000
      ]
    }
  )

Req.get!("https://httpbingo.org/json", finch: [name: MyFinch])
More commonly you'd add the custom Finch pool as part of your supervision tree in your
application.ex:
children = [
  {Finch,
   name: MyFinch,
   pools: %{
     default: [size: 70]
   }}
]
That way you can also configure a bigger pool size for the HTTP pool. You just mustn't forget to
pass along finch: [name: MyFinch] as discussed above. You could use Req.default_options/1 to make it
a global default but it's generally discouraged.
For documentation about the possible pool options and their meaning, please check out the
Finch docs on pool configuration options.
Request Options
	:finch - options for the Finch adapter. Defaults to a pool automatically started by
Req. Can include:
	:name - the name of the Finch pool.

	Finch request options, e.g. :pool_tag, :pool_timeout, :receive_timeout. See
Finch.Request.build_opt/0 and Finch.request_opt/0 for more information.

	Finch pool options, e.g.: :conn_max_idle_time, :pool_max_idle_time, :conn_opts.
See Finch.start_link/1 for more information.
Finch pool options cannot be mixed with :name option.


Examples:
Req.get!("https://httpbingo.org/json", finch: [name: MyFinch])
Req.get!("https://httpbingo.org/json", finch: [name: MyFinch, pool_tag: :bulk])
Req.get!("https://httpbingo.org/json", finch: [conn_max_idle_time: 10_000])

	:connect_options - dynamically starts (or re-uses already started) Finch pool with
the given connection options:
	:timeout - socket connect timeout in milliseconds, defaults to 30_000.

	:protocols - the HTTP protocols to use, defaults to
[:http1].

	:hostname - Mint explicit hostname, see Mint.HTTP.connect/4 for more information.

	:transport_opts - Mint transport options, see Mint.HTTP.connect/4 for more
information.

	:proxy_headers - Mint proxy headers, see Mint.HTTP.connect/4 for more information.

	:proxy - Mint HTTP/1 proxy settings, a {scheme, address, port, options} tuple.
See Mint.HTTP.connect/4 for more information.

	:client_settings - Mint HTTP/2 client settings, see Mint.HTTP.connect/4 for more
information.



	:inet6 - if set to true, uses IPv6.
If the request URL looks like IPv6 address, i.e., say, [::1], it defaults to true
and otherwise defaults to false.
This is a shortcut for setting connect_options: [transport_opts: [inet6: true]].

	:receive_timeout - socket receive timeout in milliseconds, defaults to 15_000.

	:request_timeout - response timeout in milliseconds, defaults to :infinity.
See Finch.request/3.

	:unix_socket - if set, connect through the given UNIX domain socket.

	:finch_private - a map or keyword list of private metadata to add to the Finch request.
May be useful for adding custom data when handling telemetry with Finch.Telemetry.


Examples
Custom :receive_timeout:
iex> Req.get!(url, receive_timeout: 1000)
Connecting through UNIX socket:
iex> Req.get!("http:///v1.41/_ping", unix_socket: "/var/run/docker.sock").body
"OK"
Custom connection options:
iex> Req.get!(url, connect_options: [timeout: 5000])

iex> Req.get!(url, connect_options: [protocols: [:http2]])
Connecting without certificate check (useful in development, not recommended in production):
iex> Req.get!(url, connect_options: [transport_opts: [verify: :verify_none]])
Connecting with custom certificates:
iex> Req.get!(url, connect_options: [transport_opts: [cacertfile: "certs.pem"]])
Connecting through a proxy with basic authentication:
iex> Req.new(
...>  url: "https://elixir-lang.org",
...>  connect_options: [
...>    proxy: {:http, "your.proxy.com", 8888, []},
...>    proxy_headers: [{"proxy-authorization", "Basic " <> Base.encode64("user:pass")}]
...>  ]
...> )
iex> |> Req.get!()
Transport errors are represented as Req.TransportError exceptions:
iex> Req.get("https://httpbingo.org/delay/1", receive_timeout: 0, retry: false)
{:error, %Req.TransportError{reason: :timeout}}

      


      
        Summary


  
    Functions
  


    
      
        pool_options(options)

      


        Returns Finch pool options for the given Req options.



    





      


      
        Functions


        


  
    
      
    
    
      pool_options(options)



        
          
        

    

  


  

Returns Finch pool options for the given Req options.

Req.Plug 
    



      
Runs the request against a plug instead of over the network.
This is a Req adapter, used automatically when the :plug option is set.
It requires :plug dependency:
{:plug, "~> 1.0"}
Request Options
	:plug - the plug to run the request through. It can be one of:
	A function plug: a fun(conn) or fun(conn, options) function that takes a
Plug.Conn and returns a Plug.Conn.

	A module plug: a module name or a {module, options} tuple.


Req automatically calls Plug.Conn.fetch_query_params/2 before your plug, so you can
get query params using conn.query_params.
Req also automatically parses request body using Plug.Parsers for JSON, urlencoded and
multipart requests and you can access it with conn.body_params. The raw request body of
the request is available by calling Req.Test.raw_body/1 with the conn in your tests.


Examples
This adapter is particularly useful for testing plugs:
defmodule Echo do
  def call(conn, _) do
    "/" <> path = conn.request_path
    Plug.Conn.send_resp(conn, 200, path)
  end
end

test "echo" do
  assert Req.get!("http:///hello", plug: Echo).body == "hello"
end
You can define plugs as functions too:
test "echo" do
  echo = fn conn ->
    "/" <> path = conn.request_path
    Plug.Conn.send_resp(conn, 200, path)
  end

  assert Req.get!("http:///hello", plug: echo).body == "hello"
end
which is particularly useful to create HTTP service stubs, similar to tools like
Bypass.
When testing JSON APIs, it's common to use the Req.Test.json/2 helper:
test "JSON" do
  plug = fn conn ->
    Req.Test.json(conn, %{message: "Hello, World!"})
  end

  resp = Req.get!(plug: plug)
  assert resp.status == 200
  assert resp.headers["content-type"] == ["application/json; charset=utf-8"]
  assert resp.body == %{"message" => "Hello, World!"}
end
You can simulate network errors by calling Req.Test.transport_error/2
in your plugs:
test "network issues" do
  plug = fn conn ->
    Req.Test.transport_error(conn, :timeout)
  end

  assert Req.get(plug: plug, retry: false) ==
           {:error, %Req.TransportError{reason: :timeout}}
end

Req.Brotli 
    



      
Brotli decoding using :brotli package.
This module is used by Req.Decompress on content-encoding: br.

Req.CSV 
    



      
CSV decoding using nimble_csv.
Req.Decode can use this module for .csv and text/csv responses when the :csv
decoder is enabled via the :decoders option.
Examples
Req.get!(url, decoders: [:csv]).body
#=> [["x", "y"], ["1", "2"], ["3", "4"]]
Req.CSV does NOT currently do streaming decoding:
Req.stream(
  url,
  nil,
  fn data, _resp, acc ->
    IO.inspect(data)
    {:cont, acc}
  end,
  decoders: [:csv]
)
# Output: "x,y\r\n"
# Output: "1,2\r\n"
# Output: "3,4\r\n"

Req.Gzip 
    



      
gzip decoding using :zlib.
Req.Decode can use this module for .gz, application/gzip, and application/x-gzip
responses when the :gz decoder is enabled via the :decoders option. Req.Decompress
uses it on content-encoding: gzip.

Req.JSON 
    



      
JSON decoding using Elixir's JSON module.
This module is used by Req.Decode on .json, application/json,
and application/vnd.api+json.

Req.NDJSON 
    



      
NDJSON decoding.
Each line is decoded as a separate JSON document. This module is used by Req.Decode on
application/x-ndjson and application/ndjson.
Examples
iex> {:ok, resp, acc} =
...>   Req.stream(
...>     "http://httpbingo.org/stream/2",
...>     [],
...>     fn data, _resp, acc ->
...>       IO.inspect(data)
...>       {:cont, acc}
...>     end,
...>     decoders: [text: :ndjson] # endpoint sends content-type: text/plain
...>                               # so let's force ndjson.
...>   )
# Output: %{"id" => 0, ...}
# Output: %{"id" => 1, ...}
iex> resp.status
200
iex> resp.body
nil

Req.SSE 
    



      
Server-sent events decoding using ServerSentEvents.
Each event is decoded as a map, e.g. %{event: "msg", data: "foo"}. This module is used by
Req.Decode on text/event-stream.
Per the SSE spec, an incomplete event at the end of the stream is discarded.
Examples
iex> Req.stream(
...>   "https://stream.wikimedia.org/v2/stream/recentchange",
...>   nil,
...>   fn event, _resp, acc ->
...>     %{"type" => type, "title" => title} = JSON.decode!(event.data)
...>     IO.puts("#{type}: #{title}")
...>     {:cont, acc}
...>   end
...> )
# Output: edit: File:Glacier National Park (GeoDIL number - 2068).jpg
# Output: categorize: Category:Coins of Merovingian dynasty from Gallica
# ...

Req.Tar 
    



      
Tar archive decoding using :erl_tar.
Req.Decode can use this module for .tar, .tgz, .tar.gz, and application/x-tar
responses when the :tar or :tgz decoder is enabled via the :decoders option.

      


      
        Summary


  
    Functions
  


    
      
        decode(binary)

      


        Decodes a tar archive binary into a list of {name, contents} entries.

          @spec decode(binary()) ::
  {:ok, [{charlist(), binary()}]}
  | {:error,
     %Req.ArchiveError{
       __exception__: term(),
       data: term(),
       format: term(),
       reason: term()
     }}


      


Decodes a tar archive binary into a list of {name, contents} entries.
The binary may be a plain tar archive or a gzip-compressed one (.tar.gz/.tgz); the
compression is detected automatically.
Returns {:ok, entries} or {:error, exception}.

Req.ZIP 
    



      
ZIP archive decoding using :zip.
Req.Decode can use this module for .zip and application/zip responses when the :zip
decoder is enabled via the :decoders option.

Req.Zstd 
    



      
Zstandard decoding using :zstd.
Req.Decode can use this module for .zst and application/zstd responses when the :zst
decoder is enabled via the :decoders option. Req.Decompress uses it on
content-encoding: zstd.
:zstd requires Erlang/OTP 28+.

Req.ArchiveError exception
    



      
Represents an error when unpacking archives fails, returned by the archive decoders.
See Req.Decode.

Req.ChecksumMismatchError exception
    



      
Represents a checksum mismatch error, returned when the response body does not match
the :checksum option. See Req.Checksum.

Req.DecompressError exception
    



      
Represents an error when decompression fails.

Req.HTTPError exception
    



      
Represents an HTTP protocol error.
This is a standardised exception that all Req adapters should use for HTTP-protocol-related
errors.
This exception is based on Mint.HTTPError.

Req.Test.OwnershipError exception

Req.TooManyRedirectsError exception
    



      
Represents an error when too many redirects occurred, returned by the Req.Redirect step.

Req.TransportError exception
    



      
Represents an error with the transport used by an HTTP connection.
This is a standardised exception that all Req adapters should use for transport-layer-related
errors.
This exception is based on Mint.TransportError.

Req.UnexpectedStatusError exception
    



      
An exception returned by Req.Expect when response has unexpected status.
The public fields are:
	:expected_status - the expected HTTP response status

	:actual_status - the actual HTTP response status

